INPUT LOADS ..
TITLE LINE-1 *SIMPLE STRUCTURE RUN 1, CHICAGO*
LINE-2 *BOX WITH NO WINDOWS OR INTERNAL LOADS*
LINE-3 *LOADS CALCULATION ONLY; NO SYSTEM* ..
RUN-PERIOD JAN 1 1974 THRU DEC 31 1974 ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
LOADS-REPORT SUMMARY=(LS-C,LS-D) ..
BUILDING-LOCATION LATITUDE=42.0 LONGITUDE=88.0
ALTITUDE=610
TIME-ZONE=6 AZIMUTH=30.0 ..
$ BUILDING DESCRIPTION
$ STRUCTURE WOOD FRAME WALLS AND ROOF; 4IN CONCRETE SLAB-ON-GRADE.
$ NO WINDOWS OR DOORS; ONE ZONE.
$ WALLS USING CODE-WORDS FROM DOE-2 LIBRARY ( REFERENCE MANUAL PART 2 )
$ STARTING WITH OUTSIDE MATERIAL: WOOD SHINGLES (WD01); PLYWOOD
$ (PW03); R-11 FIBER INSULATION (IN02); AND GYPSUM BOARD (GP01).
$ ROOF ROOF GRAVEL (RG01), BUILT-UP ROOFING (BR01), R-3 MINERAL BOARD
$ INSULATION (IN22), WOOD SHEATHING CEILING (WD01), AND I-F-R=.76 .
$ SLAB-ON-GRADE EFFECTIVE U-VALUE = .05 (I.E., ASSUMING 4" HEAVY CONCRETE SLAB
$ U-EFF= (U SLAB + AIR FILM) * AREA (1FT PERIMETER)/ TOTAL AREA
$ = 0.8 * 300/5000 = .05
$ INTERIOR DESIGN TEMPERATURE IS 70F. EXTERIOR DESIGN FOR CHICAGO, IL USING
$ TEST REFERENCE YEAR (TRY) WEATHER TAPE.
$ INTERIOR LOADS: NO PEOPLE, NO LIGHTS, NO EQUIPMENT AND NO INFILTRATION.
$ CONSTRUCTION TYPES
WA-1-2=LAYERS MATERIAL=(WD01,PW03,IN02,GP01) ..
RB-1-1=LAYERS MATERIAL=(RG01,BR01,IN22,WD01) I-F-R=.76 ..
WALL-1 =CONSTRUCTION LAYERS=WA-1-2 ..
ROOF-1 =CONSTRUCTION LAYERS=RB-1-1 ..
FLOOR-1 =CONSTRUCTION U = 0.05 ..
$ GENERAL SPACE DEFINITIONS
ROOM-1 =SPACE AREA = 5000
VOLUME=40000 ..
FRONT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
AZIMUTH = 180
CONSTRUCTION = WALL-1 ..
RIGHT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=100 AZIMUTH = 90
CONSTRUCTION = WALL-1 ..
BACK-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=100 Y=50 AZIMUTH = 0
CONSTRUCTION = WALL-1 ..
LEFT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
Y=50 AZIMUTH = 270
CONSTRUCTION = WALL-1 ..
TOP-1 =ROOF HEIGHT=50 WIDTH=100
X=0 Y=0 Z=8 AZIMUTH=180
TILT = 0 GND-REFLECTANCE=0
CONSTRUCTION = ROOF-1 ..
BOTTOM-1 =UNDERGROUND-FLOOR AREA = 5000
CONSTRUCTION = FLOOR-1 ..
END ..
COMPUTE LOADS ..
INPUT LOADS ..
TITLE LINE-1 *SIMPLE STRUCTURE RUN 2, CHICAGO *
LINE-2 *ADD WINDOWS, DOORS, INTERNAL LOADS*
LINE-3 *LOADS CALCULATION ONLY; NO SYSTEM* ..
RUN-PERIOD JAN 1 1974 THRU DEC 31 1974 ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
LOADS-REPORT SUMMARY= (LS-C,LS-D) ..
BUILDING-LOCATION LATITUDE=42.0 LONGITUDE=88.0
ALTITUDE=610
TIME-ZONE=6 AZIMUTH=30.0 ..
$ BUILDING DESCRIPTION
$ BUILDING SHELL IS SAME AS FOR SIMPLE STRUCTURE RUN 1 WITH THE ADDITION OF
$ WINDOWS AND DOORS.
$ WINDOW GLASS: 1/4IN PLATE DOUBLE PANE AND NO INTERNAL SHADING DEVICE.
$ DOOR GLASS: 1/2IN PLATE SINGLE PANE. THERE IS A 10FT WIDE X 4FT DEEP
$ OVERHANG AT THE FRONT DOOR DF-1.
$ INTERIOR LOADS: ADD SURFACE MOUNTED FLUORESCENT LIGHTING AT
$ 1.5 WATTS/SQFT.
$ ADD RECEPTACLES FOR EQUIPMENT AT 1 WATT/SQFT.
$ ADD PEOPLE AT 100 SQFT PER PERSON.
$ CONSTRUCTIONS AND GLASS TYPES
WA-1-2=LAYERS MATERIAL=(WD01,PW03,IN02,GP01) ..
RB-1-1=LAYERS MATERIAL=(RG01,BR01,IN22,WD01) I-F-R=.76 ..
ROOF-1 =CONSTRUCTION LAYERS=RB-1-1 ..
WALL-1 =CONSTRUCTION LAYERS=WA-1-2 ..
FLOOR-1 =CONSTRUCTION U = 0.05 ..
WINDOW-1 =GLASS-TYPE GLASS-TYPE-CODE = 3 PANES = 2 ..
DOORS =GLASS-TYPE GLASS-TYPE-CODE = 5 ..
$ OCCUPANCY SCHEDULE
OC-1 =DAY-SCHEDULE (1,8) (0.0)
(9,11) (1.0)
(12,14) (0.8,0.4,0.8)
(15,18) (1.0)
(19,21) (0.5,0.1,0.1)
(22,24) (0.0) ..
OC-2 =DAY-SCHEDULE (1,24) (0.0) ..
OC-WEEK =WEEK-SCHEDULE (WD) OC-1 (WEH) OC-2 ..
OCCUPY-1 =SCHEDULE THRU DEC 31 OC-WEEK ..
$ LIGHTING SCHEDULE
LT-1 =DAY-SCHEDULE (1,8) (0.05)
(9,14) (0.9,0.95,1.0,0.95,0.8,0.9)
(15,18) (1.0)
(19,21) (0.6,0.2,0.2)
(22,24) (0.05) ..
LT-2 =DAY-SCHEDULE (1,24) (0.05) ..
LT-WEEK =WEEK-SCHEDULE (MON,FRI) LT-1 (WEH) LT-2 ..
LIGHTS-1 =SCHEDULE THRU DEC 31 LT-WEEK ..
$ OFFICE EQUIPMENT SCHEDULE
EQ-1 =DAY-SCHEDULE (1,8) (0.02)
(9,14) (0.8)
(15,20) (0.8,0.7,0.5,0.5,0.3,0.3)
(21,24) (0.02) ..
EQ-2 =DAY-SCHEDULE (1,24) (0.02) ..
EQ-WEEK =WEEK-SCHEDULE (MON,FRI) EQ-1 (WEH) EQ-2 ..
EQUIP-1 =SCHEDULE THRU DEC 31 EQ-WEEK ..
$ SET DEFAULT VALUES
SET-DEFAULT FOR SPACE FLOOR-WEIGHT = 70 ..
SET-DEFAULT FOR WINDOW HEIGHT=4.0 GLASS-TYPE=WINDOW-1 Y=3 ..
$ SPACE DEFINITION
OFFICE =SPACE AREA = 5000 VOLUME = 40000
PEOPLE-SCHEDULE = OCCUPY-1
LIGHTING-SCHEDULE = LIGHTS-1
EQUIP-SCHEDULE = EQUIP-1
LIGHTING-TYPE = REC-FLUOR-RV
LIGHTING-W/SQFT = 1.5
LIGHT-TO-SPACE = .80
EQUIPMENT-W/SQFT = 1
NUMBER-OF-PEOPLE = 50 ..
FRONT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=0 Y=0 Z=0 AZIMUTH=180
CONSTRUCTION = WALL-1 ..
WF-1 =WINDOW WIDTH = 45 X = 10 ..
DF-1 =WINDOW WIDTH = 8 HEIGHT = 8
X = 70 Y = 0
GLASS-TYPE=DOORS OVERHANG-A 1.0
OVERHANG-W 10 OVERHANG-D 4 ..
RIGHT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=100 AZIMUTH = 90
CONSTRUCTION = WALL-1 ..
WR-1 =WINDOW WIDTH = 25 X = 12.5 ..
BACK-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=100 Y=50 AZIMUTH = 0
CONSTRUCTION = WALL-1 ..
WB-1 =WINDOW WIDTH = 45 X = 10 ..
DB-1 =WINDOW WIDTH = 7 HEIGHT = 7
X = 70 Y = 0
GLASS-TYPE=DOORS ..
LEFT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
Y=50 AZIMUTH = 270
CONSTRUCTION = WALL-1 ..
WL-1 =WINDOW WIDTH =25 X = 12.5 ..
TOP-1 =ROOF HEIGHT=50 WIDTH=100
X=0 Y=0 Z=8 AZIMUTH=180
TILT = 0 GND-REFLECTANCE=0
CONSTRUCTION = ROOF-1 ..
BOTTOM-1 =UNDERGROUND-FLOOR AREA = 5000
CONSTRUCTION = FLOOR-1 ..
END ..
COMPUTE LOADS ..
INPUT LOADS ..
TITLE LINE-1 *SIMPLE STRUCTURE RUN 3, CHICAGO *
LINE-2 *DIVIDE INTO ZONES; ADD PLENUM *
LINE-3 *DESIGN-DAY SIZING OF VAV SYSTEM *
LINE-4 *SHOW ALL REPORTS * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD AUG 3 1974 THRU AUG 5 1974 $ TO SPAN WEEKEND
JAN 5 1974 THRU JAN 7 1974 $ DITTO
APR 6 1974 THRU APR 8 1974 $ DITTO
JAN 1 1974 THRU DEC 31 1974 ..
LOADS-REPORT VERIFICATION = (ALL-VERIFICATION)
SUMMARY = (ALL-SUMMARY) ..
BUILDING-LOCATION LATITUDE=42.0 LONGITUDE=88.0
ALTITUDE=610
TIME-ZONE=6 AZIMUTH=30.0 ..
$ CHICAGO DESIGN DAYS
HOT-CLEAR-SUMMER = DESIGN-DAY
DRYBULB-HI = 91 DRYBULB-LO = 71
HOUR-HI = 15 HOUR-LO = 7
DEWPT-HI = 65.5 DEWPT-LO = 60
DHOUR-HI = 16 DHOUR-LO = 8
WIND-SPEED = 7.5 WIND-DIR = 10
CLOUD-AMOUNT = 0 CLOUD-TYPE = 0
CLEARNESS = 1 GROUND-T = 61 ..
COLD-CLOUDY-WINTER = DESIGN-DAY
DRYBULB-HI = 6 DRYBULB-LO = -4
HOUR-HI = 15 HOUR-LO = 2
DEWPT-HI = 6 DEWPT-LO = -4
DHOUR-HI = 16 DHOUR-LO = 3
WIND-SPEED = 15 WIND-DIR = 14
CLOUD-AMOUNT = 5 CLOUD-TYPE = 2
CLEARNESS = 1 GROUND-T = 46 ..
WARM-CLEAR-WINTER = DESIGN-DAY
DRYBULB-HI = 65 DRYBULB-LO = 40
HOUR-HI = 15 HOUR-LO = 7
DEWPT-HI = 40 DEWPT-LO = 35
DHOUR-HI = 16 DHOUR-LO = 8
WIND-SPEED = 15 WIND-DIR = 14
CLOUD-AMOUNT = 0 CLOUD-TYPE = 0
CLEARNESS = 1 GROUND-T = 46 ..
$ BUILDING DESCRIPTION
$ BUILDING STRUCTURE IS THE SAME AS FOR SIMPLE STRUCTURE RUNS 1 & 2 WITH THE
$ ADDITION OF A PLENUM. THE SPACES ARE ALSO REDEFINED, WITH
$ INTERIOR AND EXTERIOR AREAS SEPARATED BY PARTITIONS WITH
$ A U-VALUE OF 1.5 TO SIMULATE CONVECTIVE HEAT TRANSFER BETWEEN
$ THEM. INFILTRATION IS ALSO ADDED AT .25 AIR CHANGES/HR.
$ LIGHTING FIXTURES ARE RECESSED FLUORESCENT WITH 20% OF THE HEAT FROM LIGHTING
$ GOING TO THE CEILING PLENUM AND THEREFORE INTO THE RETURN AIR.
$ HVAC SYSTEM DESCRIPTION
$ DESIGN TEMPS COOLING 78F - HEATING 70F.
$ SYSTEM TYPE A SINGLE VARIABLE AIR VOLUME SYSTEM SERVES THE ENTIRE BUILDING.
$ THE SYSTEM HAS A DRYBULB CONTROLLED ECONOMIZER WITH A LIMIT
$ TEMP OF 65F, VARIABLE SPEED FAN MOTOR, AND VAV BOXES WITH
$ A MINIMUM STOP OF 30%. THE TEMPERATURE OF THE SUPPLY AIR IS
$ RESET BY OUTSIDE AIR - 60F AT FULL COOLING TO 65F IN WINTER.
$ MINIMUM VENTILATION AIR IS 20 CFM/PERSON. THE SYSTEM OPERATES
$ FROM 8AM TO 6PM WEEKDAYS AND IS OFF ON WEEKENDS. THERE IS A
$ NIGHT LOW LIMIT SETPOINT OF 55F TO PREVENT FREEZING. THE FAN IS
$ ALLOWED TO START AT 6AM WHEN NECESSARY FOR BLDG PICK-UP, BUT
$ IS DELAYED AS LONG AS POSSIBLE (I.E., OPTIMUM START). HEATING
$ AND COOLING ARE NOT ALLOWED TO OPERATE SIMULTANEOUSLY.
$ HVAC PLANT GAS FIRED HOT WATER GENERATOR PRESIZED AT .15 MBTUH.
$ RECIPROCATING AIR COOLED CHILLER PRESIZED AT .18 MBTUH.
$ UTILITIES NATURAL GAS AT 1.50 DOLLARS PER THERM.
$ ELECTRICITY HAS A TIME-OF-DAY CHARGE AS FOLLOWS:
$ OFF-PEAK 5 CENTS/KWH NIGHTS AND WEEKENDS
$ SHOULDER 6 CENTS/KWH 8AM TO 12 NOON AND FROM
$ 6PM TO 10 PM WEEKDAYS
$ 8AM TO 5PM SATURDAYS
$ ON-PEAK 7 CENTS/KWH 1PM TO 5PM WEEKDAYS
$ CONSTRUCTIONS AND GLASS-TYPES
WA-1-2=LAYERS MATERIAL=(WD01,PW03,IN02,GP01) ..
RB-1-1=LAYERS MATERIAL=(RG01,BR01,IN22,WD01) I-F-R=.76 ..
WALL-1 =CONSTRUCTION LAYERS=WA-1-2 ..
ROOF-1 =CONSTRUCTION LAYERS=RB-1-1 ..
CLNG-1 =CONSTRUCTION U = 0.27 .. $CEILING
SB-U =CONSTRUCTION U = 1.5 .. $PARTITION
FLOOR-1 =CONSTRUCTION U = 0.05 ..
W-1 =GLASS-TYPE GLASS-TYPE-CODE = 3 PANES = 2 ..
DOORS =GLASS-TYPE GLASS-TYPE-CODE = 5 ..
$ OCCUPANCY SCHEDULE
OC-1 =DAY-SCHEDULE (1,8) (0.0)
(9,11) (1.0)
(12,14) (0.8,0.4,0.8)
(15,18) (1.0)
(19,21) (0.5,0.1,0.1)
(22,24) (0.0) ..
OC-2 =DAY-SCHEDULE (1,24) (0.0) ..
OC-WEEK =WEEK-SCHEDULE (WD) OC-1 (WEH) OC-2 ..
OCCUPY-1 =SCHEDULE THRU DEC 31 OC-WEEK ..
$ LIGHTING SCHEDULE
LT-1 =DAY-SCHEDULE (1,8) (0.05)
(9,14) (0.9,0.95,1.0,0.95,0.8,0.9)
(15,18) (1.0)
(19,21) (0.6,0.2,0.2)
(22,24) (0.05) ..
LT-2 =DAY-SCHEDULE (1,24) (0.05) ..
LT-WEEK =WEEK-SCHEDULE (MON,FRI) LT-1 (WEH) LT-2 ..
LIGHTS-1 =SCHEDULE THRU DEC 31 LT-WEEK ..
$ OFFICE EQUIPMENT SCHEDULE
EQ-1 =DAY-SCHEDULE (1,8) (0.02)
(9,14) (0.8)
(15,20) (0.8,0.7,0.5,0.5,0.3,0.3)
(21,24) (0.02) ..
EQ-2 =DAY-SCHEDULE (1,24) (0.02) ..
EQ-WEEK =WEEK-SCHEDULE (MON,FRI) EQ-1 (WEH) EQ-2 ..
EQUIP-1 =SCHEDULE THRU DEC 31 EQ-WEEK ..
$ INFILTRATION SCHEDULE
INFIL-SCH =SCHEDULE THRU MAR 31 (ALL) (1,24) (1)
THRU OCT 31 (ALL) (1,24) (0)
THRU DEC 31 (ALL) (1,24) (1) ..
$ SET DEFAULT VALUES
SET-DEFAULT FOR SPACE FLOOR-WEIGHT=70 ..
SET-DEFAULT FOR WINDOW HEIGHT=4.0 GLASS-TYPE=W-1 Y=3 ..
$ GENERAL SPACE DEFINITION
OFFICE =SPACE-CONDITIONS
PEOPLE-SCHEDULE =OCCUPY-1
NUMBER-OF-PEOPLE =50
PEOPLE-HEAT-GAIN =400
LIGHTING-SCHEDULE =LIGHTS-1
LIGHTING-TYPE =REC-FLUOR-RV
LIGHT-TO-SPACE =.80
LIGHTING-W/SQFT =1.5
EQUIP-SCHEDULE =EQUIP-1
EQUIPMENT-W/SQFT =1
INF-METHOD =AIR-CHANGE
AIR-CHANGES/HR =0.25
INF-SCHEDULE =INFIL-SCH ..
$ SPECIFIC SPACE DETAILS
PLENUM-1 =SPACE ZONE-TYPE=PLENUM
VOLUME=10000 FLOOR-WEIGHT=5
AREA=5000 Z=8 ..
WALL-1PF =EXTERIOR-WALL HEIGHT = 2 WIDTH = 100
AZIMUTH = 180
CONSTRUCTION = WALL-1 ..
WALL-1PR =EXTERIOR-WALL HEIGHT = 2 WIDTH = 50
AZIMUTH = 90 X = 100
CONSTRUCTION = WALL-1 ..
WALL-1PB =EXTERIOR-WALL HEIGHT = 2 WIDTH = 100
AZIMUTH = 0 X = 100
Y = 50
CONSTRUCTION = WALL-1 ..
WALL-1PL =EXTERIOR-WALL HEIGHT = 2 WIDTH = 50
AZIMUTH = 270 Y = 50
CONSTRUCTION = WALL-1 ..
TOP-1 =ROOF HEIGHT=50 WIDTH=100
X=0 Y=0 Z=2 AZIMUTH = 180
TILT=0 GND-REFLECTANCE=0
CONSTRUCTION = ROOF-1 ..
SPACE1-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1056 VOLUME = 8448
NUMBER-OF-PEOPLE = 11 ..
FRONT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=0 Y=0 Z=0 AZIMUTH = 180
CONSTRUCTION = WALL-1 ..
WF-1 =WINDOW WIDTH = 45 X = 10 ..
DF-1 =WINDOW WIDTH = 8 HEIGHT = 8
X = 70 Y = 0
GLASS-TYPE = DOORS
OVERHANG-A=1 OVERHANG-B=.5
OVERHANG-W=10 OVERHANG-D=4 ..
C1-1 =INTERIOR-WALL AREA = 1056 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F1-1 =UNDERGROUND-FLOOR AREA = 1056
CONSTRUCTION = FLOOR-1 ..
SB12 =INTERIOR-WALL AREA = 135.76 NEXT-TO SPACE2-1
CONSTRUCTION = SB-U ..
SB14 =INTERIOR-WALL LIKE SB12 NEXT-TO SPACE4-1 ..
SB15 =INTERIOR-WALL AREA = 608 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE2-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 456 VOLUME = 3648
NUMBER-OF-PEOPLE = 5 ..
RIGHT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=100 Y=0 Z=0 AZIMUTH = 90
CONSTRUCTION = WALL-1 ..
WR-1 =WINDOW WIDTH = 25 X = 12.5 ..
C2-1 =INTERIOR-WALL AREA = 456 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F2-1 =UNDERGROUND-FLOOR AREA = 456
CONSTRUCTION = FLOOR-1 ..
SB23 =INTERIOR-WALL AREA = 135.76 NEXT-TO SPACE3-1
CONSTRUCTION = SB-U ..
SB25 =INTERIOR-WALL AREA = 208 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE3-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1056 VOLUME = 8448
NUMBER-OF-PEOPLE = 11 ..
BACK-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=100 Y=50 Z=0 AZIMUTH = 0
CONSTRUCTION = WALL-1 ..
WB-1 =WINDOW WIDTH = 45 X = 10 ..
DB-1 =WINDOW WIDTH = 7 HEIGHT = 7
X = 70 Y = 0
GLASS-TYPE=DOORS ..
C3-1 =INTERIOR-WALL AREA = 1056 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F3-1 =UNDERGROUND-FLOOR AREA = 1056
CONSTRUCTION = FLOOR-1 ..
SB34 =INTERIOR-WALL AREA = 135.8 NEXT-TO SPACE4-1
CONSTRUCTION = SB-U ..
SB35 =INTERIOR-WALL AREA = 608 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE4-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 456 VOLUME = 3648
NUMBER-OF-PEOPLE = 5 ..
LEFT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=0 Y=50 Z=0 AZIMUTH = 270
CONSTRUCTION = WALL-1 ..
WL-1 =WINDOW WIDTH = 25 X = 12.5 ..
C4-1 =INTERIOR-WALL AREA = 456 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F4-1 =UNDERGROUND-FLOOR AREA = 456
CONSTRUCTION = FLOOR-1 ..
SB45 =INTERIOR-WALL AREA = 208 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE5-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1976 VOLUME =15808
NUMBER-OF-PEOPLE = 20 ..
C5-1 =INTERIOR-WALL AREA = 1976 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F5-1 =UNDERGROUND-FLOOR AREA = 1976
CONSTRUCTION = FLOOR-1 ..
$ LOADS HOURLY REPORT
HR-SCH-1 =SCHEDULE THRU AUG 4 (ALL)(1,24)(0)
THRU AUG 5 (ALL)(1,24)(1)
THRU DEC 31 (ALL)(1,24)(0) ..
LRB-1 =REPORT-BLOCK VARIABLE-TYPE=GLOBAL
VARIABLE-LIST=(4,17,15) .. $ dbt, wind speed, hor. solar $
LRB-2 =REPORT-BLOCK VARIABLE-TYPE=BUILDING
VARIABLE-LIST=(19) .. $ building cooling load $
LDS-REP-1 =HOURLY-REPORT REPORT-SCHEDULE=HR-SCH-1
REPORT-BLOCK=(LRB-1,LRB-2) ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY=(ALL-SUMMARY) ..
$ SYSTEMS SCHEDULES
FAN-1 =DAY-SCHEDULE (1,6)(0)(7,8)(-999)(9,18)(1)(19,24)(0) ..
FAN-2 =DAY-SCHEDULE (1,24) (0) ..
FAN-SCHED =SCHEDULE THRU DEC 31 (WD) FAN-1 (WEH) FAN-2 ..
HEAT-1 =DAY-SCHEDULE (1,8) (55) (9,18) (70) (19,24) (55) ..
HEAT-2 =DAY-SCHEDULE (1,24) (55) ..
HEAT-WEEK =WEEK-SCHEDULE (MON,FRI) HEAT-1 (WEH) HEAT-2 ..
HEAT-SCHED =SCHEDULE THRU DEC 31 HEAT-WEEK ..
COOLOFF =SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
HEATOFF =SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
COOL-1 =DAY-SCHEDULE (1,8) (99) (9,18) (78) (19,24) (99) ..
COOL-2 =DAY-SCHEDULE (1,24) (99) ..
COOL-WEEK =WEEK-SCHEDULE (MON,FRI) COOL-1 (WEH) COOL-2 ..
COOL-SCHED =SCHEDULE THRU DEC 31 COOL-WEEK ..
R1 DAY-RESET-SCH SUPPLY-HI 65 SUPPLY-LO 60
OUTSIDE-LO 30 OUTSIDE-HI 75 ..
SAT-RESET RESET-SCHEDULE THRU DEC 31 (ALL) R1 ..
$ SYSTEM DESCRIPTION
ZAIR =ZONE-AIR OA-CFM/PER=20 ..
CONTROL =ZONE-CONTROL DESIGN-HEAT-T=70 DESIGN-COOL-T=76
HEAT-TEMP-SCH= HEAT-SCHED
COOL-TEMP-SCH= COOL-SCHED
THERMOSTAT-TYPE=REVERSE-ACTION ..
SPACE1-1 =ZONE ZONE-AIR=ZAIR SIZING-OPTION= ADJUST-LOADS
ZONE-CONTROL=CONTROL ..
SPACE2-1 =ZONE LIKE SPACE1-1 ..
SPACE3-1 =ZONE LIKE SPACE1-1 ..
SPACE4-1 =ZONE LIKE SPACE1-1 ..
SPACE5-1 =ZONE LIKE SPACE1-1 ..
PLENUM-1 =ZONE ZONE-TYPE=PLENUM SIZING-OPTION= ADJUST-LOADS
DESIGN-HEAT-T=50 DESIGN-COOL-T=95 ..
S-CONT =SYSTEM-CONTROL COOLING-SCHEDULE= COOLOFF
HEATING-SCHEDULE= HEATOFF
HEAT-SET-T=65
COOL-CONTROL=RESET
COOL-RESET-SCH=SAT-RESET
MIN-SUPPLY-T=60 ..
S-FAN =SYSTEM-FANS FAN-SCHEDULE=FAN-SCHED FAN-CONTROL=SPEED
SUPPLY-STATIC=5.5 SUPPLY-EFF=.55
NIGHT-CYCLE-CTRL=CYCLE-ON-ANY ..
S-TERM =SYSTEM-TERMINAL REHEAT-DELTA-T=58
MIN-CFM-RATIO=0.3 ..
SYST-1 =SYSTEM SYSTEM-TYPE=VAVS
SYSTEM-CONTROL= S-CONT
SYSTEM-FANS= S-FAN
SYSTEM-TERMINAL= S-TERM
ECONO-LIMIT-T=65
RETURN-AIR-PATH=PLENUM-ZONES
PLENUM-NAMES=(PLENUM-1)
ZONE-NAMES=(SPACE5-1,SPACE1-1,SPACE2-1
SPACE3-1,SPACE4-1,PLENUM-1) ..
$ SYSTEMS HOURLY REPORT
HR-SCH-2 =SCHEDULE THRU AUG 4 (ALL)(1,24)(0)
THRU AUG 5 (ALL)(1,24)(1)
THRU DEC 31 (ALL)(1,24)(0) ..
SRB-1 =REPORT-BLOCK VARIABLE-TYPE=GLOBAL
VARIABLE-LIST=(8,7) .. $ outside dbt, wbt $
SRB-2 =REPORT-BLOCK VARIABLE-TYPE=SPACE1-1
VARIABLE-LIST=(7,6,8) .. $ thermostat setpoint,
$ zone temp, extraction rate
SRB-3 =REPORT-BLOCK VARIABLE-TYPE=SYST-1
VARIABLE-LIST=(2,4,6) .. $ coil leaving air temp,
$ return air temp, coil load
SYSS-REP-1 =HOURLY-REPORT REPORT-SCHEDULE=HR-SCH-2
REPORT-BLOCK=(SRB-1,SRB-2,SRB-3) ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
PLANT-REPORT SUMMARY=(ALL-SUMMARY)
VERIFICATION = (ALL-VERIFICATION) ..
$ HOT-WATER GENERATOR
HWG =PLANT-EQUIPMENT TYPE=HW-BOILER SIZE=-999 ..
PLANT-PARAMETERS HERM-REC-COND-TYPE=AIR ..
$ AIR-COOLED RECIPROCATING CHILLER
CHIL1 =PLANT-EQUIPMENT TYPE=HERM-REC-CHLR SIZE=-999 ..
PLANT-COSTS PROJECT-LIFE=25 DISCOUNT-RATE=5 ..
ENERGY-RESOURCE RESOURCE=ELECTRICITY ..
ENERGY-RESOURCE RESOURCE=NATURAL-GAS ENERGY/UNIT=100000
UNIT-NAME=THERMS ..
$ PLANT HOURLY REPORT
HR-SCH-3 =SCHEDULE THRU AUG 4 (ALL)(1,24)(0)
THRU AUG 5 (ALL)(1,24)(1)
THRU DEC 31 (ALL)(1,24)(0) ..
PRB-1 =REPORT-BLOCK VARIABLE-TYPE=HERM-REC-CHLR
VARIABLE-LIST=(1,10,16) .. $ chiller load,
$ part load ratio, EIR
PLT-REP-1 =HOURLY-REPORT REPORT-SCHEDULE=HR-SCH-3
REPORT-BLOCK=(PRB-1) ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
ECONOMICS-REPORT S=(ALL-SUMMARY)
V=(ALL-VERIFICATION) ..
ELEC-TARIFF=UTILITY-RATE RESOURCE=ELECTRICITY
ENERGY-CHG-SCH=ENERGY-SCH
ESCALATION=7 ..
ENERGY-SCH =SCHEDULE THRU DEC 31 (WD) (1,8)(.05) $OFF-PEAK
(9,12)(.06) $SHOULDER
(13,17)(.07) $PEAK
(18,22)(.06) $SHOULDER
(23,24)(.05) $OFF-PEAK
(SAT) (1,8)(.05) $OFF-PEAK
(9,17)(.06) $SHOULDER
(18,24)(.05) $OFF-PEAK
(SUN,HOL) (1,24)(.05) .. $OFF-PEAK
GAS-RATE =UTILITY-RATE RESOURCE=NATURAL-GAS
ENERGY-CHG = .6 ..
END ..
COMPUTE ECONOMICS ..
INPUT LOADS ..
TITLE LINE-1 *SIMPLE STRUCTURE RUN 3A, CHICAGO *
LINE-2 *INCREASED ROOF INSULATION * ..
RUN-PERIOD JAN 1 1974 THRU DEC 31 1974 ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
LOADS-REPORT SUMMARY = (LS-C,LS-D)
VERIFICATION = (LV-B,LV-D) ..
BUILDING-LOCATION LATITUDE=42.0 LONGITUDE=88.0
ALTITUDE=610
TIME-ZONE=6 AZIMUTH=30.0 ..
$ BUILDING DESCRIPTION
$ STRUCTURE THE BUILDING IS IDENTICAL TO THAT IN RUN 3 ABOVE EXCEPT
$ THAT THE ROOF HAS AN ADDITIONAL INCH OF INSULATION.
$ SYSTEMS AND PLANT SIZING IS TAKEN FROM RESULTS OF RUN 3.
$ ECONOMICS SPECIFICATIONS ARE THE SAME AS RUN3, BUT INCLUDE THE COSTS
$ OF THE IMPROVEMENTS ADDED FOR THE RUN AND THE RESULTS OF RUN 3
$ AS A BASELINE.
$
$ BASELINE BASELINE ECONOMICS DATA ARE TAKEN FROM
$ SIMPLE STRUCTURE RUN 3 REPORTS ES-A AND ES-C.
$
$ IMPROVEMENT 5000 SQFT OF INSULATION AT 1.10 DOLLARS/SQFT
$ CONSTRUCTION AND GLASS-TYPES
ROO-1 =LAYERS =MAT=(RG01,BR01,IN46,WD01) I-F-R .76 ..
WA-1-2 =LAYERS =MAT=(WD01,PW03,IN02,GP01) ..
WALL-1 =CONSTRUCTION LAYERS=WA-1-2 ..
ROOF-1 =CONSTRUCTION LAYERS=ROO-1 ..
CLNG-1 =CONSTRUCTION U = 0.27 ..
SB-U =CONSTRUCTION U = 1.5 ..
FLOOR-1 =CONSTRUCTION U = 0.05 ..
W-1 =GLASS-TYPE GLASS-TYPE-CODE = 3 PANES = 2 ..
DOORS =GLASS-TYPE GLASS-TYPE-CODE = 5 ..
$ OCCUPANCY SCHEDULE
OC-1 =DAY-SCHEDULE (1,8) (0.0)
(9,11) (1.0)
(12,14) (0.8,0.4,0.8)
(15,18) (1.0)
(19,21) (0.5,0.1,0.1)
(22,24) (0.0) ..
OC-2 =DAY-SCHEDULE (1,24) (0.0) ..
OC-WEEK =WEEK-SCHEDULE (WD) OC-1 (WEH) OC-2 ..
OCCUPY-1 =SCHEDULE THRU DEC 31 OC-WEEK ..
$ LIGHTING SCHEDULE
LT-1 =DAY-SCHEDULE (1,8) (0.05)
(9,14) (0.9,0.95,1.0,0.95,0.8,0.9)
(15,18) (1.0)
(19,21) (0.6,0.2,0.2)
(22,24) (0.05) ..
LT-2 =DAY-SCHEDULE (1,24) (0.05) ..
LT-WEEK =WEEK-SCHEDULE (MON,FRI) LT-1 (WEH) LT-2 ..
LIGHTS-1 =SCHEDULE THRU DEC 31 LT-WEEK ..
$ OFFICE EQUIPMENT SCHEDULE
EQ-1 =DAY-SCHEDULE (1,8) (0.02)
(9,14) (0.4,0.9,0.9,0.9,0.9,0.9)
(15,20) (0.8,0.7,0.5,0.5,0.3,0.3)
(21,24) (0.02) ..
EQ-2 =DAY-SCHEDULE (1,24) (0.2) ..
EQ-WEEK =WEEK-SCHEDULE (MON,FRI) EQ-1 (WEH) EQ-2 ..
EQUIP-1 =SCHEDULE THRU DEC 31 EQ-WEEK ..
$ INFILTRATION SCHEDULE
INFIL-SCH =SCHEDULE THRU MAR 31 (ALL) (1,24) (1)
THRU OCT 31 (ALL) (1,24) (0)
THRU DEC 31 (ALL) (1,24) (1) ..
$ SET DEFAULT VALUES
SET-DEFAULT FOR SPACE FLOOR-WEIGHT=70 ..
SET-DEFAULT FOR EXTERIOR-WALL CONSTRUCTION=WALL-1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4.0 GLASS-TYPE=W-1 Y=3 ..
$ GENERAL SPACE DEFINITION
OFFICE =SPACE-CONDITIONS PEOPLE-SCHEDULE =OCCUPY-1
NUMBER-OF-PEOPLE =50
PEOPLE-HEAT-GAIN =400
LIGHTING-SCHEDULE =LIGHTS-1
LIGHTING-TYPE =REC-FLUOR-RV
LIGHT-TO-SPACE =.80
LIGHTING-W/SQFT =1.5
EQUIP-SCHEDULE =EQUIP-1
EQUIPMENT-W/SQFT =1
INF-METHOD =AIR-CHANGE
AIR-CHANGES/HR =0.25
INF-SCHEDULE =INFIL-SCH ..
$ SPECIFIC SPACE DETAILS
PLENUM-1 =SPACE ZONE-TYPE=PLENUM AREA=5000
VOLUME=10000 Z=8 FLOOR-WEIGHT=5 ..
WALL-1PF =EXTERIOR-WALL HEIGHT = 2 WIDTH = 100
AZIMUTH = 180 ..
WALL-1PR =EXTERIOR-WALL HEIGHT = 2 WIDTH = 50
AZIMUTH = 90 X = 100 ..
WALL-1PB =EXTERIOR-WALL HEIGHT = 2 WIDTH = 100
X = 100 Y = 50 AZIMUTH = 0 ..
WALL-1PL =EXTERIOR-WALL HEIGHT = 2 WIDTH = 50
AZIMUTH = 270 Y = 50 ..
TOP-1 =ROOF HEIGHT=50 WIDTH=100
X=0 Y=0 Z=2 AZIMUTH = 180
TILT=0 GND-REFLECTANCE=0
CONSTRUCTION = ROOF-1 ..
SPACE1-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1056 VOLUME = 8448
NUMBER-OF-PEOPLE = 11 ..
FRONT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=0 Y=0 Z=0 AZIMUTH = 180 ..
WF-1 =WINDOW WIDTH = 45 X = 10 ..
DF-1 =WINDOW WIDTH = 8 HEIGHT = 8
X = 70 Y = 0 GLASS-TYPE=DOORS
OVERHANG-A 1 OVERHANG-B .5
OVERHANG-W 10 OVERHANG-D 4 ..
C1-1 =INTERIOR-WALL AREA = 1056 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F1-1 =UNDERGROUND-FLOOR AREA = 1056 CONSTRUCTION = FLOOR-1 ..
SB12 =INTERIOR-WALL AREA=135.76 NEXT-TO SPACE2-1
CONSTRUCTION = SB-U ..
SB14 =INTERIOR-WALL LIKE SB12 NEXT-TO SPACE4-1 ..
SB15 =INTERIOR-WALL AREA 608 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE2-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 456 VOLUME = 3648
NUMBER-OF-PEOPLE = 5 ..
RIGHT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=100 Y=0 Z=0 AZIMUTH = 90 ..
WR-1 =WINDOW WIDTH = 25 X = 12.5 ..
C2-1 =INTERIOR-WALL AREA = 456 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F2-1 =UNDERGROUND-FLOOR AREA = 456 CONSTRUCTION = CLNG-1 ..
SB23 =INTERIOR-WALL AREA = 135.76 NEXT-TO SPACE3-1
CONSTRUCTION = SB-U ..
SB25 =INTERIOR-WALL AREA = 208 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE3-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1056 VOLUME = 8448
NUMBER-OF-PEOPLE = 11 ..
BACK-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 100
X=100 Y=50 Z=0 AZIMUTH = 0 ..
WB-1 =WINDOW WIDTH = 45 X = 10 ..
DB-1 =WINDOW WIDTH = 7 HEIGHT = 7
X = 70 Y = 0 GLASS-TYPE=DOORS ..
C3-1 =INTERIOR-WALL AREA = 1056 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F3-1 =UNDERGROUND-FLOOR AREA = 1056
CONSTRUCTION = FLOOR-1 ..
SB34 =INTERIOR-WALL AREA = 135.8 NEXT-TO SPACE4-1
CONSTRUCTION = SB-U ..
SB35 =INTERIOR-WALL AREA = 608 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE4-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 456 VOLUME = 3648
NUMBER-OF-PEOPLE = 5 ..
LEFT-1 =EXTERIOR-WALL HEIGHT = 8 WIDTH = 50
X=0 Y=50 Z=0 AZIMUTH = 270 ..
WL-1 =WINDOW WIDTH = 25 X = 12.5 ..
C4-1 =INTERIOR-WALL AREA = 456 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F4-1 =UNDERGROUND-FLOOR AREA = 456
CONSTRUCTION = FLOOR-1 ..
SB45 =INTERIOR-WALL AREA = 208 NEXT-TO SPACE5-1
CONSTRUCTION = SB-U ..
SPACE5-1 =SPACE SPACE-CONDITIONS = OFFICE
AREA = 1976 VOLUME = 15808
NUMBER-OF-PEOPLE = 20 ..
C5-1 =INTERIOR-WALL AREA = 1976 NEXT-TO PLENUM-1
CONSTRUCTION = CLNG-1 ..
F5-1 =UNDERGROUND-FLOOR AREA = 1976 CONSTRUCTION = FLOOR-1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY=(SS-A,SS-J) ..
$ SYSTEMS SCHEDULES
FAN-1 =DAY-SCHEDULE (1,6)(0)(7,8)(-999)(9,18)(1)(19,24)(0) ..
FAN-2 =DAY-SCHEDULE (1,24) (0) ..
FAN-SCHED =SCHEDULE THRU DEC 31 (WD) FAN-1 (WEH) FAN-2 ..
HEAT-1 =DAY-SCHEDULE (1,8) (55) (9,18) (70) (19,24) (55) ..
HEAT-2 =DAY-SCHEDULE (1,24) (55) ..
HEAT-WEEK =WEEK-SCHEDULE (MON,FRI) HEAT-1 (WEH) HEAT-2 ..
HEAT-SCHED =SCHEDULE THRU DEC 31 HEAT-WEEK ..
COOLOFF =SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
HEATOFF =SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
COOL-1 =DAY-SCHEDULE (1,8) (99) (9,18) (78) (19,24) (99) ..
COOL-2 =DAY-SCHEDULE (1,24) (99) ..
COOL-WEEK =WEEK-SCHEDULE (MON,FRI) COOL-1 (WEH) COOL-2 ..
COOL-SCHED =SCHEDULE THRU DEC 31 COOL-WEEK ..
R1 =DAY-RESET-SCH SUPPLY-HI=60 SUPPLY-LO=52
OUTSIDE-LO=30 OUTSIDE-HI=75 ..
SAT-RESET =RESET-SCHEDULE THRU DEC 31 (ALL) R1 ..
$ SYSTEM DESCRIPTION
ZAIR =ZONE-AIR OA-CFM/PER=20 ..
CONTROL =ZONE-CONTROL DESIGN-HEAT-T=70 DESIGN-COOL-T=76
HEAT-TEMP-SCH= HEAT-SCHED
COOL-TEMP-SCH= COOL-SCHED
THERMOSTAT-TYPE=REVERSE-ACTION ..
$ FOLLOWING AIR FLOWS ARE FROM RUN 3 SV-A REPORT,
$ DIVIDED BY ALTITUDE MULTIPLIER
SPACE1-1 =ZONE ZONE-AIR=ZAIR SIZING-OPTION=ADJUST-LOADS
ZONE-CONTROL=CONTROL ASSIGNED-CFM=2133 ..
SPACE2-1 =ZONE LIKE SPACE1-1 ASSIGNED-CFM=957 ..
SPACE3-1 =ZONE LIKE SPACE1-1 ASSIGNED-CFM=1509 ..
SPACE4-1 =ZONE LIKE SPACE1-1 ASSIGNED-CFM=953 ..
SPACE5-1 =ZONE LIKE SPACE1-1 ASSIGNED-CFM=1814 ..
PLENUM-1 =ZONE ZONE-TYPE=PLENUM SIZING-OPTION=ADJUST-LOADS
DESIGN-HEAT-T=50 DESIGN-COOL-T=95 ..
S-CONT =SYSTEM-CONTROL COOLING-SCHEDULE= COOLOFF
HEATING-SCHEDULE= HEATOFF
HEAT-SET-T=65
COOL-CONTROL=RESET
COOL-RESET-SCH=SAT-RESET
MIN-SUPPLY-T=60 ..
S-FAN =SYSTEM-FANS FAN-SCHEDULE=FAN-SCHED FAN-CONTROL=SPEED
SUPPLY-STATIC=5.5 SUPPLY-EFF=.55
NIGHT-CYCLE-CTRL=CYCLE-ON-ANY ..
S-TERM =SYSTEM-TERMINAL REHEAT-DELTA-T=58
MIN-CFM-RATIO=0.3 ..
SYST-1 =SYSTEM SYSTEM-TYPE=VAVS
SUPPLY-CFM=7366
SYSTEM-CONTROL= S-CONT
SYSTEM-FANS= S-FAN
SYSTEM-TERMINAL= S-TERM
ECONO-LIMIT-T=65
RETURN-AIR-PATH=PLENUM-ZONES
PLENUM-NAMES=(PLENUM-1)
ZONE-NAMES=(SPACE5-1,SPACE1-1,SPACE2-1
SPACE3-1,SPACE4-1,PLENUM-1) ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
PLANT-REPORT SUMMARY=(PS-A,BEPS) ..
$ EQUIPMENT DESCRIPTION
$ HOT-WATER BOILER
SBOIL1 =PLANT-EQUIPMENT TYPE=HW-BOILER SIZE=.457 .. $ SIZE FROM RUN 3
PLANT-PARAMETERS HERM-REC-COND-TYPE=AIR ..
$ AIR-COOLED RECIPROCATING CHILLER
CHIL1 =PLANT-EQUIPMENT TYPE=HERM-REC-CHLR SIZE=.222 .. $ SIZE FROM RUN 3
PLANT-COSTS PROJECT-LIFE=25 DISCOUNT-RATE=5 ..
ENERGY-RESOURCE RESOURCE=ELECTRICITY ..
ENERGY-RESOURCE RESOURCE=NATURAL-GAS ENERGY/UNIT=100000
UNIT-NAME=THERMS ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
$ COST OF ADDED ROOF INSULATION
ROOF-INSUL =COMPONENT-COST UNIT-NAME=*SQFT* NUMBER-OF-UNITS=5000
FIRST-COST=0.80 INSTALL-COST=0.30 ..
$ BASELINE COSTS (INCLUDES COST OF BASELINE PLANT EQUIPMENT)
BASELINE
$ following is from "FIRST COST, INCLUDING INSTALLATION",
$ in Run 3, Report ES-B
FIRST-COST=29298
$ following is from total "REPLACEMENTS"
$ in Run 3, Report ES-B
REPLACE-COST=0
$ following is from "ENERGY COST THIS RUN"
$ in Run 3, Report ES-A
ENERGY-COST = (4369,4431,4493,4557,4622,4688,4756,
4824,4894,4966,5038,5113,5188,5265,5344,5424,
5505,5588,5673,5759,5847,5936,6027,6120,6215)
$ following is from "OPRNS COST -- THIS RUN, TOTAL"
$ in Run 3, Report ES-A
OPERATIONS-COST = (249,238,314,216,205,272,
186,412,236,161,212,146,139,828,126,279,
159,109,104,531,94,124,85,189,108)
$ following is from "ANNUAL ENERGY USE THIS RUN, AT SITE"
$ in Run 3, Report ES-C
ENERGY-USE-SITE = 363.93
$ following is from "ANNUAL ENERGY USE THIS RUN, AT SOURCE"
$ in Run 3, Report ES-C
ENERGY-USE-SRC = 709.67 ..
ECONOMICS-REPORT SUMMARY=(ALL-SUMMARY) VERIFICATION=(ALL-VERIFICATION) ..
ELEC-TARIFF=UTILITY-RATE RESOURCE=ELECTRICITY
ENERGY-CHG-SCH=ENERGY-SCH
ESCALATION=7 ..
ENERGY-SCH =SCHEDULE THRU DEC 31 (WD) (1,8)(.05) $OFF-PEAK
(9,12)(.06) $SHOULDER
(13,17)(.07) $PEAK
(18,22)(.06) $SHOULDER
(23,24)(.05) $OFF-PEAK
(SAT) (1,8)(.05) $OFF-PEAK
(9,17)(.06) $SHOULDER
(18,24)(.05) $OFF-PEAK
(SUN,HOL) (1,24)(.05) .. $OFF-PEAK
GAS-RATE =UTILITY-RATE RESOURCE=NATURAL-GAS
ENERGY-CHG = .6 ..
END ..
COMPUTE ECONOMICS ..
STOP ..
|
|
|
Products and Solutions 
