INPUT LOADS ..
TITLE LINE-1 *31-STORY OFFICE BLDG, CHICAGO - LOAD1*
LINE-2 *STD ASHRAE WEIGHTING FACTORS * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
LOADS-REPORT SUMMARY=(LS-C,LS-D) ..
RUN-PERIOD JAN 1 1988 THRU DEC 31 1988 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
$ BUILDING DESCRIPTION
$ STRUCTURE STEEL FRAME WITH 4IN CONCRETE FLOORS AND ROOF. 31 OCCUPIED
$ STORIES, 13FT FLOOR TO FLOOR HEIGHT, 9FT CEILINGS. RETURN
$ AIR CEILING PLENUMS ARE NOT DEFINED PER SE -- INPUT USES THE
$ SIMPLER APPROACH OF RETURN-AIR-PATH = DUCT.
$ CURTAIN WALL USING CODE-WORDS FROM DOE-2 LIBRARY ( REFERENCE MANUAL PART 2 )
$ AND STARTING WITH OUTSIDE WORKING INWARD: 1/4IN SPANDREL GLASS
$ ( NOT IN LIBRARY - SEE MATERIAL SPGL ); 2IN POLYSTRENE INSUL
$ R-8 (IN35); STEEL BACKPANEL (AS01); 2IN AIRSPACE (AL21);
$ 3/4IN GYPSUM BOARD FINISH (GP03) .
$ ROOF ROOF GRAVEL (RG02); BUILT-UP ROOFING (BR01); 3IN ROOF INSUL R-8
$ (IN76); 4IN CONCRETE (CC03); INSIDE-FILM-RESISTANCE .76 .
$ WINDOWS DOUBLE-GLAZED TINTED, SOLAR TRANSMITTANCE=.53, GLASS TYPE CODE=5.
$ WINDOWS HAVE INSIDE BLINDS WITH A 70% PROBABILITY OF BEING PULLED
$ IF TRANSMITTED DIRECT SOLAR RADIATION EXCEEDS 40BTUH PER SQFT.
$ BLINDS ARE CONSIDERED TO BE REOPENED WITH A PROBABILITY OF 50%
$ WHEN TRANSMITTED DIRECT SOLAR IS LESS THAN 40BTUH PER SQFT.
$ INTERIORS CEILINGS ARE SUSPENDED ACCOUSTIC TILE.
$ PARTITIONS SIMULATE CONVECTIVE HEAT TRANSFER BETWEEN CORE AND
$ PERIMETER SPACES USING A U-VALUE OF 1.5 BTUH/SQFT-F
$ SPACE LOADS LIGHTING IS RECESSED FLUORESCENT AT 1.5 WATTS/SQFT.
$ OFFICE EQUIPMENT IS 1 WATTS/SQFT.
$ PEOPLE: 100SQFT/PERSON FOR PERIMETER SPACES
$ 200SQFT/PERSON FOR CORE AREAS.
$ INFILTRATION IS .3 AIR CHANGES/HR FOR PERIMETER AREAS WHEN FANS
$ ARE OFF, AND .06 AIR CHANGES/HR WHEN FANS ARE ON.
$ HVAC DESCRIPTIONS ARE GIVEN WITH EACH INDIVIDUAL SYSTEM AND PLANT INPUT.
$ MATERIALS NOT IN DOE-2 LIBRARY
SPGS=MATERIAL TH=.0208 COND=.590 DENS=172. S-H=.20 ..
$ WALL CONSTRUCTIONS
ROOFER LAYERS MAT (RG02,BR01,IN76,CC03) I-F-R .76 ..
WALLER LAYERS MAT (SPGS,IN35,AS01,AL21,GP03) ..
RF =CONSTRUCTION LAYERS=ROOFER ..
WL1 =CONSTRUCTION LAYERS=WALLER ..
BW =CONSTRUCTION U=.05 ..
SB-U =CONSTRUCTION U=1.5 ..
$ GLASS DESCRIPTION
GT1 GLASS-TYPE G-T-C 5 PANES 2 ..
$ SCHEDULES
OC1 =DAY-SCHEDULE (1,8) (0.) (9,10) (1.)
(11,13) (.8,.4,.8) (14,24) (1.,1.,1.,
.3,.1,.1,.1,0.,0.,0.,0.) ..
OC2 =DAY-SCHEDULE (1,24) (0.0) ..
PEOPLE =WEEK-SCHEDULE (MON,FRI) OC1 (WEH) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 PEOPLE ..
L1 =DAY-SCHEDULE (1,6) (.05) (7,24) (.1,.9,.9,
.95,.95,.95,.8,.8,.9,.9,.95,.8,.7,.6,
.4,.3,.2,.2) ..
L2 =DAY-SCHEDULE (1,24) (.05) ..
LIGHTS =WEEK-SCHEDULE (MON,FRI) L1 (WEH) L2 ..
LT1 =SCHEDULE THRU DEC 31 LIGHTS ..
ES1 =DAY-SCHEDULE (1,8) (0.) (9,20) (.35,.50,
.55,.9,.6,.8,.7,.75,.3,.3,.5,.05)
(21,24) (0.0) ..
ES2 =DAY-SCHEDULE (1,24) (0.0) ..
EQUIP =WEEK-SCHEDULE (MON,FRI) ES1 (WEH) ES2 ..
EQ1 =SCHEDULE THRU DEC 31 EQUIP ..
I1 =DAY-SCHEDULE (1,7) (1.) (8,18) (0.2)
(19,24) (1.) ..
I2 =DAY-SCHEDULE (1,24) (1.) ..
INFILT =WEEK-SCHEDULE (MON,FRI) I1 (WEH) I2 ..
INF1 =SCHEDULE THRU DEC 31 INFILT ..
SHADE-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.5) ..
CLOSE-SHADE =SCHEDULE THRU DEC 31 (ALL) (1,24) (40) ..
OPEN-PROB =SCHEDULE THRU DEC 31 (ALL) (1,24) (.5) ..
$ SPACE DESCRIPTIONS
OFFICE =SPACE-CONDITIONS TEMPERATURE=(75) FLOOR-WEIGHT=70
LIGHTING-W/SQFT=1.5 EQUIPMENT-W/SQFT=1
PEOPLE-HEAT-GAIN=450
EQUIP-SCHEDULE=EQ1 LIGHTING-SCHEDULE=LT1
PEOPLE-SCHEDULE=OCCUP AIR-CHANGES/HR=.3
INF-SCHEDULE=INF1 LIGHT-TO-SPACE=.80
INF-METHOD=AIR-CHANGE
LIGHTING-TYPE=REC-FLUOR-RV ..
A-STORAGE =SPACE TEMPERATURE=(75) FLOOR-WEIGHT=150
VOLUME=400000 AREA=20000
LIGHTING-W/SQFT=1.5
LIGHTING-SCHEDULE=LT1 ..
UNDERGROUND-WALL AREA=12000 CONSTRUCTION=BW ..
UNDERGROUND-FLOOR AREA=20000 CONSTRUCTION=BW ..
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=13.0 AZIMUTH=180 ..
SET-DEFAULT FOR WINDOW HEIGHT=6.5 Y=2.5 GLASS-TYPE=GT1
MAX-SOLAR-SCH=CLOSE-SHADE
WIN-SHADE-TYPE=MOVABLE-INTERIOR
SHADING-SCHEDULE=SHADE-MULT
OPEN-SHADE-SCH=OPEN-PROB
SUN-CTRL-PROB=.7 ..
RZ1 =SPACE SPACE-CONDITIONS=OFFICE VOLUME=107100
AREA=11900 NUMBER-OF-PEOPLE=60
AIR-CHANGES/HR=0.01 X=15 Y=15 Z=390 ..
ROOF1 =ROOF HEIGHT=170 WIDTH=70 AZIMUTH=180 TILT=0
GND-REFLECTANCE=0 CONSTRUCTION=RF ..
IRZ2 =INTERIOR-WALL NEXT-TO RZ2 AREA=1530
CONSTRUCTION=SB-U ..
IRZ3 =INTERIOR-WALL NEXT-TO RZ3 AREA=630
CONSTRUCTION=SB-U ..
IRZ4 =INTERIOR-WALL LIKE IRZ2 NEXT-TO RZ4 ..
IRZ5 =INTERIOR-WALL LIKE IRZ3 NEXT-TO RZ5 ..
RZ2 =SPACE SPACE-CONDITIONS=OFFICE VOLUME=24975
AREA=2775 NUMBER-OF-PEOPLE=28
AZIMUTH=-90 X=100 Z=390 ..
E2 =EXTERIOR-WALL WIDTH=200 CONSTRUCTION=WL1 ..
W2 =WINDOW WIDTH=200 ..
ROOF2 =ROOF HEIGHT=15 WIDTH=185 AZIMUTH=180 TILT=0
GND-REFLECTANCE=0 CONSTRUCTION=RF ..
RZ3 =SPACE SPACE-CONDITIONS= OFFICE VOLUME=11475
AREA=1275 NUMBER-OF-PEOPLE=13
AZIMUTH=180 X=100 Y=200 Z=390 ..
E3 =EXTERIOR-WALL WIDTH=100 CONSTRUCTION=WL1 ..
W3 =WINDOW WIDTH=100 ..
ROOF3 =ROOF HEIGHT=15 WIDTH=85 AZIMUTH=180 TILT=0
GND-REFLECTANCE=0 CONSTRUCTION=RF ..
RZ4 =SPACE LIKE RZ2 AZIMUTH=90 X=0 Y=200 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
ROOF LIKE ROOF2 ..
RZ5 =SPACE LIKE RZ3 AZIMUTH=0 X=0 Y=0 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
ROOF LIKE ROOF3 ..
TZ1 =SPACE LIKE RZ1 FLOOR-MULTIPLIER=30 Z=195 ..
ITZ2 =INTERIOR-WALL LIKE IRZ2 NEXT-TO TZ2 ..
ITZ3 =INTERIOR-WALL LIKE IRZ3 NEXT-TO TZ3 ..
ITZ4 =INTERIOR-WALL LIKE IRZ2 NEXT-TO TZ4 ..
ITZ5 =INTERIOR-WALL LIKE IRZ3 NEXT-TO TZ5 ..
TZ2 =SPACE LIKE RZ2 FLOOR-MULTIPLIER=30 Z=195 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE RZ3 FLOOR-MULTIPLIER=30 Z=195 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
TZ4 =SPACE LIKE RZ4 FLOOR-MULTIPLIER=30 Z=195 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ5 =SPACE LIKE RZ5 FLOOR-MULTIPLIER=30 Z=195 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
TITLE LINE-4 *RUN 1 DUAL-DUCT VARIABLE VOLUME SYSTEM* ..
$ HVAC SYSTEM DESCRIPTION
$ DESIGN TEMPS COOLING 76F HEATING 70F.
$ SYSTEM TYPE A SINGLE DUAL DUCT VARIABLE VOLUME SYSTEM SERVES THE ENTIRE
$ BUILDING. THE SYSTEM HAS A DRY BULB CONTROLLED ECONOMIZER WITH
$ A LIMIT TEMP OF 68F, INLET VANES ON BOTH SUPPLY AND RETURN FANS,
$ AND THE DD/VAV BOXES HAVE A MINIMUM STOP OF 30%. THE TEMPERATURE
$ OF THE COLD DECK SUPPLY AIR IS CONTROLLED BY THE WARMEST ZONE
$ AND THE HOT DECK AIR BY THE COLDEST ZONE. MINIMUM VENTILATION
$ AIR IS 20 CFM/PERSON AND THE SYSTEM OPERATES FROM 7AM TO 6PM ON
$ WEEKDAYS AND IS OFF WEEKENDS AND HOLIDAYS. THERE IS A LOW
$ LIMIT SETPOINT OF 55F TO PREVENT FREEZING. FROM MAY 1 THRU NOV 1
$ THE SYSTEM IS ALLOWED TO CYCLE ON TO PROVIDE NIGHT VENTILATION
$ FOR FREE OA COOLING BUT ONLY IF THE SPACE TEMP IS ABOVE 74F.
SYSTEMS-REPORT SUMMARY=(SS-A,SS-C,SS-D,SS-J) ..
$ SCHEDULES
HRS1 = DAY-SCHEDULE (1,7) (0) (8,18) (1) (19,24) (0) ..
HRS2 = DAY-SCHEDULE (1,24) (0) ..
DAYS1 = WEEK-SCHEDULE (MON,FRI) HRS1 (WEH) HRS2 ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS1 .. $ FANS $
SUMMER-VENT = SCHEDULE THRU MAY 1 (ALL) (1,24) (0)
THRU NOV 1 (ALL) (1,24) (1)
THRU DEC 31 (ALL) (1,24) (0) ..
VENT-SETPT = SCHEDULE THRU DEC 31 (ALL) (1,24) (74) ..
COOLON = SCHEDULE THRU DEC 31 (ALL) (1,24) (55) ..
HEATON = SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
HRSH1 = DAY-SCHEDULE (1,7) (55) (8,18) (70) (19,24) (55) ..
HRSH2 = DAY-SCHEDULE (1,24) (55) ..
DAYHEAT = WEEK-SCHEDULE (MON,FRI) HRSH1 (WEH) HRSH2 ..
THEAT = SCHEDULE THRU DEC 31 DAYHEAT .. $ HEATING $
HRSC1 = DAY-SCHEDULE (1,7) (99) (8,18) (76) (19,24) (99) ..
HRSC2 = DAY-SCHEDULE (1,24) (99) ..
DAYCOOL = WEEK-SCHEDULE (MON,FRI) HRSC1 (WEH) HRSC2 ..
TCOOL = SCHEDULE THRU DEC 31 DAYCOOL .. $ COOLING $
$ ZONE SUB-COMMANDS
SAIR = ZONE-AIR OA-CFM/PER=20 ..
CONTROL = ZONE-CONTROL HEAT-TEMP-SCH=THEAT COOL-TEMP-SCH=TCOOL
DESIGN-HEAT-T=70 DESIGN-COOL-T=74
THERMOSTAT-TYPE=REVERSE-ACTION ..
$ ZONE DESCRIPTION
RZ1 = ZONE ZONE-TYPE=CONDITIONED ZONE-AIR=SAIR
ZONE-CONTROL=CONTROL CFM/SQFT=.9 ..
RZ2 = ZONE LIKE RZ1 ..
RZ3 = ZONE LIKE RZ1 ..
RZ4 = ZONE LIKE RZ1 ..
RZ5 = ZONE LIKE RZ1 ..
TZ1 = ZONE LIKE RZ1 ..
TZ2 = ZONE LIKE TZ1 ..
TZ3 = ZONE LIKE TZ1 ..
TZ4 = ZONE LIKE TZ1 ..
TZ5 = ZONE LIKE TZ1 ..
A-STORAGE= ZONE LIKE RZ1 AIR-CHANGES/HR=4 OA-CHANGES=0.5 ..
$ SYSTEM SUB-COMMANDS
S-CTRL = SYSTEM-CONTROL COOLING-SCHEDULE=COOLON
HEATING-SCHEDULE=HEATON
HEAT-CONTROL=COLDEST COOL-CONTROL=WARMEST
MAX-SUPPLY-T=105 MIN-SUPPLY-T=55 ..
S-FAN = SYSTEM-FANS FAN-SCHEDULE=AHU-SCHED FAN-CONTROL=INLET
SUPPLY-STATIC=5.5 SUPPLY-EFF=0.55
RETURN-STATIC=2.0 RETURN-EFF=0.55
NIGHT-VENT-CTRL=SCHEDULED+DEMAND
NIGHT-VENT-SCH=SUMMER-VENT
NIGHT-VENT-RATIOS=(1,1,1,0,0,0)
NIGHT-CYCLE-CTRL=CYCLE-ON-FIRST ..
S-TERM = SYSTEM-TERMINAL MIN-CFM-RATIO=0.3 ..
$ SYSTEMS DESCRIPTION
DUAL-DUCT = SYSTEM SYSTEM-TYPE=DDS SYSTEM-CONTROL=S-CTRL
SYSTEM-FANS=S-FAN VENT-TEMP-SCH=VENT-SETPT
SYSTEM-TERMINAL=S-TERM RETURN-AIR-PATH=DUCT
ECONO-LIMIT-T=68 ZONE-NAMES=(RZ1,RZ2,RZ3,
RZ4,RZ5,TZ1,TZ2,TZ3,TZ4,TZ5,A-STORAGE)
SUPPLY-CFM=750000 ..
PLANT1 = PLANT-ASSIGNMENT SYSTEM-NAMES = (DUAL-DUCT)
INT-ELEC-KW = 100 $ FOR ELEVATORS
INT-ELEC-SCH = OCCUP
DHW-SIZE=0
DHW-GAL/MIN = 2.22
DHW-SCH = OCCUP ..
OC1 =DAY-SCHEDULE (1,8) (0.) (9,10) (1.)
(11,13) (.8,.4,.8) (14,24) (1.,1.,1.,
.3,.1,.1,.1,0.,0.,0.,0.) ..
OC2 =DAY-SCHEDULE (1,24) (0.0) ..
PEOPLE =WEEK-SCHEDULE (MON,FRI) OC1 (WEH) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 PEOPLE ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
PLANT1 = PLANT-ASSIGNMENT ..
$ PLANT DESCRIPTION
$ SCREW TYPE CHILLERS ARE ALLOWED TO RUN ONLY IF OA TEMPERATURE IS ABOVE 60F.
$ THE GAS BOILER IS ALLOWED TO RUN ONLY IF OA TEMPERATURE IS BELOW 60F.
$ THESE LIMITS ARE PLACED IN SYSTEMS INPUT VIA COOLING AND HEATING SCHEDULES.
$ ALL PIECES OF EQUIPMENT ARE ALLOWED TO SIZE AUTOMATICALLY.
$ THE CHILLED WATER PUMPS ARE VARIABLE SPEED WHEREAS THE HEATING PUMPS
$ ARE CONSTANT SPEED (FLOW). CURVE-FIT COMMANDS ARE USED TO REPLACE THE STANDARD
$ HERMETIC CENTRIFUGAL CHILLER DEFAULT CURVES AND THUS SIMULATE A SCREW TYPE
$ CHILLER WITH MULTIPLE COMPRESSORS.
PLANT-REPORT SUMMARY=(PS-A,BEPS) ..
SBOIL =PLANT-EQUIPMENT TYPE=HW-BOILER SIZE=-999 INSTALLED-NUMBER=2 ..
DHWH =PLANT-EQUIPMENT TYPE=DHW-HEATER SIZE -999 INSTALLED-NUMBER=2 ..
PLANT-PARAMETERS HCIRC-PUMP-TYPE=FIXED-SPEED
CCIRC-PUMP-TYPE=VARIABLE-SPEED ..
CMPC =PLANT-EQUIPMENT TYPE=HERM-CENT-CHLR SIZE=-999
INSTALLED-NUMBER=2 ..
CTOWER =PLANT-EQUIPMENT TYPE=COOLING-TWR SIZE=-999 ..
PART-LOAD-RATIO TYPE=HERM-CENT-CHLR
MIN-RATIO=0.1 MAX-RATIO=1.05 OPERATING-RATIO=0.4 E-I-R=.23 ..
DIAGNOSTIC COMMENTS ..
BLR-HIR-FPLR CURVE-FIT TYPE LINEAR
DATA (1.,1.) (.1,.109) ..
SCREW-EIR-FPLR CURVE-FIT TYPE QUADRATIC
DATA (1.0,1.0) (.8,.7) (.6,.45) (.4,.25) (.2,.13) ..
SCREW-CAP-FT CURVE-FIT TYPE BI-QUADRATIC
DATA (44,85,1.0) (40,75,.97) (40,85,.94) (40,95,.90) (44,75,1.03)
(44,95,.96) (50,75,1.13) (50,85,1.1) (50,95,1.06) ..
SCREW-EIR-FT CURVE-FIT TYPE BI-QUADRATIC
DATA (44,85,1.0) (40,75,.88) (40,85,1.06) (40,95,1.26) (44,75,.84)
(44,95,1.18) (50,75,.79) (50,85,.93) (50,95,1.09) ..
DIAGNOSTIC WARNINGS ..
EQUIPMENT-QUAD
HW-BOILER-HIR-FPLR BLR-HIR-FPLR
HERM-CENT-EIR-FPLR SCREW-EIR-FPLR
HERM-CENT-CAP-FT SCREW-CAP-FT
HERM-CENT-EIR-FT SCREW-EIR-FT ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
ECONOMICS-REPORT S (ES-D,ES-E,ES-F) ..
$ ENERGY COST DESCRIPTION
$ THE INPUT FOR UTILITY RATES IS THE SIMPLEST POSSIBLE, USING UNIFORM RATES
$ FOR BOTH GAS AND ELECTRICITY. THERE IS A FIXED MONTHLY CHARGE AND A RATE
$ LIMITATION ON ELECTRICITY OF 7 CENTS/KWH. THE DEMAND CHARGE IS A NOMINAL
$ FLAT RATE OF 5 DOLLARS/KW YEAR-AROUND.
ELEC-RATE = UTILITY-RATE RESOURCE=ELECTRICITY
MONTH-CHGS = (2000)
ENERGY-CHG = .055
DEMAND-CHGS = (5)
RATE-LIMITATION = .07 ..
GAS-RATE = UTILITY-RATE RESOURCE=NATURAL-GAS
ENERGY-CHG =.70 .. $ DOLLARS/THERM
END ..
COMPUTE ECONOMICS ..
INPUT SYSTEMS ..
TITLE LINE-2 *RUN 2 VARIABLE AIR VOLUME SYSTEM *
LINE-4 *ELECTRIC THERMOSTATIC BASEBOARDS *
LINE-5 *WARM-UP CYCLE USES GAS HEAT* ..
$ HVAC SYSTEM DESCRIPTION
$ DESIGN TEMPS COOLING 78F HEATING 70F.
$ SYSTEM TYPE A SINGLE VARIABLE AIR VOLUME SYSTEM SERVES THE ENTIRE BUILDING.
$ THE SYSTEM HAS A DRY BULB CONTROLLED ECONOMIZER WITH A LIMIT
$ TEMP OF 68F. THE FAN HAS INLET VANES.
$ THE VAV BOXES HAVE A MINIMUM STOP OF 25%.
$ ELECTRIC BASEBOARDS IN ALL PERIMETER SPACES ARE
$ SUFFICIENTLY LARGE TO HEAT THE SPACE BUT NOT PICK UP THE HEATING
$ LOAD ON A COLD WINTER MORNING; THEREFORE, A GAS WARM-UP CYCLE IS
$ IS PROVIDED WHICH MINIMIZES THE USE OF THE ELECTRIC BASEBOARDS
$ AND REDUCES THE ELECTRIC DEMAND CHARGES. IT IS VERY DIFFICULT
$ TO SIMULATE THE DYNAMICS OF THIS CONTROL STRATEGY CORRECTLY AS
$ ON SOME MORNINGS SPACES ARE UNDERHEATED, AND ON OTHERS THEY ARE
$ OVERHEATED. THE OPERATOR OF THE BUILDING WOULD IN FACT NEED TO
$ TUNE THE SUPPLY AIR TEMPERATURE SETPOINT TO ELIMINATE THE
$ PROBLEM.
$ THE SUPPLY AIR TEMPERATURE IS SET AT 100F FOR ONE HOUR ON WINTER
$ MORNINGS AND THE CONTROL OF THE VAV BOXES OPENS THE BOXES
$ FULL FOR THOSE HOURS. THE SUPPLY AIR TEMPERATURE IS 60F AT ALL
$ OTHER TIMES. MINIMUM VENTILATION AIR IS 20 CFM/PERSON AND THE
$ FAN OPERATES FROM 7AM TO 6PM WEEKDAYS AND IS OFF ON WEEKENDS AND
$ HOLIDAYS. THERE IS A NIGHT LOW LIMIT SETTING FOR PERIMETER
$ THERMOSTATS TO HOLD SPACE AT 55F. THE FANS DO NOT RUN AT NIGHT
$ BUT CAN CYCLE ON AS EARLY 12 PM TO HOLD SETBACK. THE MINIMUM OA
$ DAMPERS ARE HELD CLOSED DURING MORNING STARTUP YEAR ROUND,
$ HOWEVER THE ECONOMIZER DAMPERS ARE ACTIVATED IF NEEDED.
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
SYSTEMS-REPORT SUMMARY=(SS-A,SS-D,SS-J) ..
$ SCHEDULES
HRS1 = DAY-SCHEDULE (1,7) (0) (8,18) (1) (19,24) (0) ..
HRS2 = DAY-SCHEDULE (1,24) (0) ..
DAYS1 = WEEK-SCHEDULE (MON,FRI) HRS1 (WEH) HRS2 ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS1 .. $ FANS $
HRSH1 = DAY-SCHEDULE (1,8) (55) (9,18) (70) (19,24) (55) ..
HRSH2 = DAY-SCHEDULE (1,24) (55) ..
DAYHEAT = WEEK-SCHEDULE (MON,FRI) HRSH1 (WEH) HRSH2 ..
THEAT = SCHEDULE THRU DEC 31 DAYHEAT .. $ HEATING $
HRSC1 = DAY-SCHEDULE (1,7) (99) (8,18) (78) (19,24) (99) ..
HRSC2 = DAY-SCHEDULE (1,24) (99) ..
DAYCOOL = WEEK-SCHEDULE (MON,FRI) HRSC1 (WEH) HRSC2 ..
TCOOL = SCHEDULE THRU DEC 31 DAYCOOL .. $ COOLING $
COOLON = SCHEDULE THRU DEC 31 (ALL) (1,24) (55) ..
HEATON = SCHEDULE THRU DEC 31 (ALL) (1,24) (60) ..
REV-STAT-ACT = SCHEDULE THRU MAR 15 (ALL) (1,8)(1) (9,24)(-999)
THRU DEC 15 (ALL) (1,24) (-999)
THRU DEC 31 (ALL) (1,8)(1) (9,24)(-999) ..
SA1 = DAY-SCHEDULE (1,8)(110) (9,18)(60) (19,24)(110) ..
SA2 = DAY-SCHEDULE (1,8)(90) (9,18)(60) (19,24)(90) ..
SAT-SETPT = SCHEDULE THRU MAR 15 (MON) SA1 (TUE,FRI) SA2 (WEH) (1,24)(110)
THRU MAY 15 (WD) SA2 (WEH) (1,24)(90)
THRU SEP 15 (ALL) (1,24)(55)
THRU OCT 15 (WD) SA2 (WEH) (1,24)(90)
THRU DEC 31 (MON) SA1 (TUE,FRI) SA2 (WEH) (1,24)(110) ..
OA-DAMPER-POS = SCHEDULE THRU DEC 31 (ALL)(1,8)(.01)(9,18)(-999)(19,24)(.01) ..
$ ZONE SUB-COMMANDS
ZAIR = ZONE-AIR OA-CFM/PER=20 ..
CONTROL = ZONE-CONTROL DESIGN-HEAT-T=70 DESIGN-COOL-T=74
HEAT-TEMP-SCH=THEAT COOL-TEMP-SCH=TCOOL
BASEBOARD-CTRL=THERMOSTATIC
THERMOSTAT-TYPE=REVERSE-ACTION ..
$ ZONE DESCRIPTION
RZ1 = ZONE ZONE-AIR=ZAIR ZONE-CONTROL=CONTROL
MIN-CFM-SCH=REV-STAT-ACT CFM/SQFT=1
BASEBOARD-RATING=-55000 ..
RZ2 = ZONE LIKE RZ1 BASEBOARD-RATING=-140000 ..
RZ3 = ZONE LIKE RZ2 B-R=-69000 ..
RZ4 = ZONE LIKE RZ2 ..
RZ5 = ZONE LIKE RZ3 ..
TZ1 = ZONE LIKE RZ1 ..
TZ2 = ZONE LIKE RZ2 B-R=-120000 ..
TZ3 = ZONE LIKE TZ2 B-R=-60000 ..
TZ4 = ZONE LIKE TZ2 ..
TZ5 = ZONE LIKE TZ3 ..
A-STORAGE= ZONE LIKE RZ1 AIR-CHANGES/HR=4 OA-CHANGES=0.5 ..
$ SYSTEM SUB-COMMANDS
S-CTRL = SYSTEM-CONTROL COOLING-SCHEDULE=COOLON
HEATING-SCHEDULE=HEATON COOL-CONTROL = SCHEDULED
HEAT-SET-T=100 COOL-SET-SCH=SAT-SETPT
MIN-SUPPLY-T=55 MAX-SUPPLY-T=100
MIN-HUMIDITY=25 ..
S-FAN = SYSTEM-FANS FAN-SCHEDULE=AHU-SCHED FAN-CONTROL=INLET
SUPPLY-STATIC=5.5 SUPPLY-EFF=0.55
RETURN-STATIC=2.0 RETURN-EFF=0.53 ..
S-TERM = SYSTEM-TERMINAL REHEAT-DELTA-T=20 MIN-CFM-RATIO=0.25 ..
$ SYSTEM DESCRIPTION
BLDG = SYSTEM SYSTEM-TYPE=VAVS SYSTEM-CONTROL=S-CTRL
SYSTEM-FANS=S-FAN MIN-AIR-SCH=OA-DAMPER-POS
SYSTEM-TERMINAL=S-TERM RETURN-AIR-PATH=DUCT
BASEBOARD-SOURCE=ELECTRIC PREHEAT=HOT-WATER
HEAT-SOURCE=HOT-WATER HUMIDIFIER-TYPE=HOT-WATER
ECONO-LIMIT-T=68 ZONE-NAMES=(RZ1,RZ2,RZ3,RZ4,
RZ5,TZ1,TZ2,TZ3,TZ4,TZ5) ..
BASMT-SYS = SYSTEM SYSTEM-TYPE=SZRH MAX-SUPPLY-T=105
MIN-SUPPLY-T=55 SUPPLY-STATIC=2.5
SUPPLY-EFF=.5 FAN-SCHEDULE=AHU-SCHED
HEATING-SCHEDULE=HEATON HEAT-SOURCE=ELECTRIC
COOLING-SCHEDULE=COOLON
ZONE-NAMES=(A-STORAGE) ..
PLANT1 = PLANT-ASSIGNMENT SYSTEM-NAMES = (BLDG,BASMT-SYS)
INT-ELEC-KW = 100 $ FOR ELEVATORS
INT-ELEC-SCH = OCCUP
DHW-SIZE=0
DHW-GAL/MIN = 2.22
DHW-SCH = OCCUP ..
OC1 =DAY-SCHEDULE (1,8) (0.) (9,10) (1.)
|
Products and Solutions 
