INPUT LOADS ..
TITLE LINE-1 * MEDICAL OFFICE BUILDING, CHICAGO*
LINE-2 * WATER LOOP HEAT PUMP WITH STORAGE *
LINE-3 * SAMP3.INP RUN 1 * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD JAN 1 1988 THRU DEC 31 1988 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
LOADS-REPORT SUMMARY=(LS-B,LS-C,LS-D) ..
$ BUILDING DESCRIPTION
$ STRUCTURE REINFORCED CONCRETE CONSTRUCTION WITH 4IN CONCRETE FLOORS AND ROOF
$ 10FT FLOOR TO FLOOR HEIGHT, TWO STORIES HIGH. RETURN AIR PLENUMS
$ ARE NOT DEFINED.
$ WALLS USING CODE WORDS FROM THE DOE-2 LIBRARY (REFERENCE MANUAL PART 2)
$ AND STARTING WITH THE OUTSIDE SURFACE AND MOVING INWARD:
$ 2IN PRECAST CONCRETE PANEL (CC03); 2IN POLYSTRENE INSULATION
$ R-8 (IN35); 3IN AIRSPACE (AL21); 5/8IN GYPSUM BOARD (GP04);
$ 3/4IN FINISH PLASTER.
$ ATRIUM ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 6IN CONCRETE (CC04); INSIDE FILM RESISTANCE .76
$ OFFICE ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 2 FT AIR SPACE (AL33); 3/4IN LAY-IN ACCOUSTIC TILE (AC03);
$ INSIDE-FILM-RESISTANCE .76.
$ FLOORS FIRST FL IS SLAB-ON-GRADE EFFECTIVE U-VALUE OF ENTIRE AREA .05.
$ WINDOWS OFFICE AREA 4FT HIGH AND FULL WIDTH OF EACH WALL, EXCEPT SOUTH
$ WALL WHERE THERE ARE NO WINDOWS. GLASS IS DOUBLE PANE TINTED
$ WITH A SOLAR TRANSMITTANCE OF .53. WINDOWS HAVE INSIDE DRAPES
$ THAT HAVE A PROBABILITY OF.7 OF BEING PULLED WHEN TRANSMITTED
$ DIRECT RADIATION IS GREATER THAN 40 BTUH. DRAPES ARE THEN REOPEN-
$ ED WITH A PROBABILITY OF .2 WHENEVER SOLAR DROPS BELOW 40BTUH.
$ ATRIUM GLASS IS THE SAME AS OFFICE GLASS EXCEPT THAT IT DOES NOT
$ HAVE DRAPES. THERE ARE TWO MAIN SECTIONS OF GLASS 29' WIDE BY
$ 30' HIGH WITH OVERHANGS AND SIDE FINS. NOTICE THAT THE SKETCH
$ OF THE BUILDING INDICATES A LARGE OVERHANG WHICH WOULD BE VERY
$ DIFFICULT TO BUILD. THIS WAS THE WAY IT WAS SIMULATED AS THIS
$ METHOD IS EQUIVALENT TO MULTIPLE SURFACES THAT PROVIDE THE SAME
$ SHADING GEOMETRY.
$ INTERIORS CEILINGS ARE SIMULATED AS PART OF THE ROOF STRUCTURE ON THE TOP
$ FLOOR. PARTITIONS SIMULATE A GLASS WALL BETWEEN ATRIUM AND
$ OFFICE SPACES, BUT WALLS BETWEEN INTERIOR AND EXTERIOR OFFICES
$ ARE NOT DEFINED. WALLS BETWEEN THE EQUIPMENT ROOM AND OFFICES
$ HAVE A U-VALUE OF .28.
$ SPACE LOADS LIGHTING IS RECESSED FLUORSCENT NON VENTED AT 1.5 WATTS/SQFT IN
$ THE OFFICES AND 1 WATT/SQFT IN THE ATRIUM.
$ PEOPLE IN OFFICES IS CALCULATED BY DOE-2 AT 150SQFT/PERSON.
$ INFILTRATION IS SET AT .2 AIRCHANGES/HR WHEN FANS ARE OFF AND AT
$ .1 AIRCHANGE WHEN FANS ARE ON.
$ EQUIPMENT IN OFFICES IS SET AT 1 WATTS/SQFT
$ CONSTRUCTIONS
ROOF-O =LAYERS MAT=(BR01,IN76,CC03,AL33,AC03) I-F-R=.76 ..
ROOF-A =LAYERS MAT=(BR01,IN76,CC04) I-F-R .76 ..
OFF-ROF =CONSTRUCTION LAYERS ROOF-O ..
ATR-ROF =CONSTRUCTION LAYERS ROOF-A ..
WALL-1 =LAYERS MAT=(CC33,IN35,AL21,GP04,GP04) ..
WL1 =CONSTRUCTION LAYERS=WALL-1 ..
BW1 =CONSTRUCTION U=.05 ..
BW2 =CONSTRUCTION U=.0001 ..
WL2 =CONSTRUCTION U=1.05 $ ATRIUM GLASS PARTITIONS $ ..
WL3 =CONSTRUCTION U=.28 $ INTERIOR PARTITIONS $ ..
$ GLASS DESCRIPTION
GT1 =GLASS-TYPE GLASS-TYPE-CODE 5 PANES 2 ..
GT2 =GLASS-TYPE G-T-C 5 PANES 2 ..
$ SCHEDULES
OC1 =DAY-SCHEDULE (1,9) (0) (10,12) (1) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
OC2 =DAY-SCHEDULE (1,24) (.2) ..
OCCUPANCY =WEEK-SCHEDULE (MON,TUE) OC1 (WED) OC2
(THU,SAT) OC1 (SUN,HOL) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 OCCUPANCY ..
L1 =DAY-SCHEDULE (1,6) (.2) (7,12) (.9) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
L2 =DAY-SCHEDULE (1,24) (.2) ..
LIGHTS =WEEK-SCHEDULE (MON,TUE) L1 (WED) L2
(THU,SAT) L1 (SUN,HOL) L2 ..
LT1 =SCHEDULE THRU DEC 31 LIGHTS ..
ES1 =DAY-SCHEDULE (1,9) (0) (10,21) (.9) (22,24) (.4) ..
ES2 =DAY-SCHEDULE (1,9) (0) (10,24) (.4) ..
EQUIPMENT =WEEK-SCHEDULE (MON,TUE) ES1 (WED) ES2
(THU,SAT) ES1 (SUN,HOL) ES2 ..
EQ1 =SCHEDULE THRU DEC 31 EQUIPMENT ..
I1 =DAY-SCHEDULE (1,9) (1) (10,21) (.5) (22,24) (1) ..
INFILTRAT =WEEK-SCHEDULE (ALL) I1 ..
INF1 =SCHEDULE THRU DEC 31 INFILTRAT ..
SHADE-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.6) ..
COND-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.90) ..
CLOSE-SHADE =SCHEDULE THRU DEC 31 (ALL) (1,24) (40) ..
REOPEN-PROB =SCHEDULE THRU DEC 31 (ALL) (1,24) (.2) ..
$ BUILDING SHADE BY ANOTHER BUILDING
$ FOR PURPOSE OF DEMONSTRATION ASSUME THAT THERE IS ANOTHER BUILDING IN
$ ALIGNMENT WITH THE MEDICAL BLDG BUT 150FT TO THE WEST. IT IS 170FT TALL
$ AND 110FT WIDE. THE INPUT TO REPRESENT THIS AS A SHADING SURFACE IS:
BUILDING-SHADE H=170 W=110 AZ=90 TILT=90 X=-150 ..
$ SET DEFAULTS
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=10 AZIMUTH=180
CONSTRUCTION=WL1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4 Y=4 GLASS-TYPE=GT1
MAX-SOLAR-SCH=CLOSE-SHADE SUN-CTRL-PROB .7
WIN-SHADE-TYPE=MOVABLE-INTERIOR
SHADING-SCHEDULE=SHADE-MULT
CONDUCT-SCHEDULE=COND-MULT
OPEN-SHADE-SCH=REOPEN-PROB ..
$ SPACE DESCRIPTION
OFFICE =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=70
EQUIPMENT-W/SQFT=1 EQUIP-SCHEDULE=EQ1
LIGHTING-W/SQFT=1.5 LIGHTING-SCHEDULE=LT1
INF-METHOD=AIR-CHANGE AIR-CHANGES/HR=.2
LIGHTING-TYPE=SUS-FLUOR
PEOPLE-HG-LAT=200 PEOPLE-HG-SENS=250
PEOPLE-SCHEDULE=OCCUP AREA/PERSON=150 ..
ATRIUM =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=100
LIGHTING-SCHEDULE=LT1
LIGHTING-TYPE=INCAND
LIGHTING-W/SQFT=1
INF-SCHEDULE=INF1 AIR-CHANGES/HR=.2
INF-METHOD=AIR-CHANGE ..
BZ1 =SPACE S-C=OFFICE AREA=3230 VOLUME=29070
AZ=90 Y=200 ..
E1 =EXTERIOR-WALL WIDTH=200 ..
W1 =WINDOW WIDTH=200 ..
E1S =EXTERIOR-WALL W=17 AZ=90 X=200 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
BZ2 =SPACE S-C=OFFICE AREA=1660 VOLUME=14940
AZ=180 X=100 Y=200 ..
E2 =EXTERIOR-WALL WIDTH=100 ..
W2 =WINDOW WIDTH=100 ..
UNDERGROUND-FLOOR AREA=1660 CONS=BW1 ..
BZ3 =SPACE LIKE BZ1 AZ=-90 X=100 Y=0 ..
E3 =EXTERIOR-WALL LIKE E1 ..
W3 =WINDOW LIKE W1 ..
E3S =EXTERIOR-WALL W=17 AZ=270 Y=17 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
TZ1 =SPACE LIKE BZ1 Z=10 ..
R1 =ROOF H=17 W=200 AZ=180 TILT=0 Z=10
CONS=OFF-ROF ..
EXTERIOR-WALL LIKE E1 ..
WINDOW LIKE W1 ..
EXTERIOR-WALL LIKE E1S ..
TZ2 =SPACE LIKE BZ2 Z=10 ..
ROOF LIKE R1 H=20 W=83 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE BZ3 Z=10 ..
ROOF LIKE R1 H=17 W=180 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
EXTERIOR-WALL LIKE E3S ..
IZ1 =SPACE S-C=OFFICE AREA=3540 VOLUME=70800
AZ=90 X=17 Y=180 ..
IN1 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ1 CONS=WL2 ..
IN2 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ2 CONS=WL2 ..
IN3 =INTERIOR-WALL AREA=586 NEXT-TO EQUIP-RM CONS=WL3 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 Y=18 Z=20 ..
EXTERIOR-WALL H=20 W=18 AZ=90 X=180 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
IZ2 =SPACE LIKE IZ1 AZ=-90 X=83 Y=0 ..
INTERIOR-WALL LIKE IN1 NEXT-TO ATZ1 ..
INTERIOR-WALL LIKE IN2 NEXT-TO ATZ2 ..
INTERIOR-WALL LIKE IN3 ..
EXTERIOR-WALL H=20 W=18 AZ=270 Y=18 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 X=160 Y=18 Z=20 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
ATZ1 =SPACE S-C=ATRIUM AREA=1800 VOLUME=16200
X=35 Y=40
SOURCE-TYPE = HOT-WATER
SOURCE-BTU/HR = 30000
SOURCE-SENSIBLE = 0.0
SOURCE-SCHEDULE = OCCUP ..
ATROOF-1 =ROOF HEIGHT=66.6 WIDTH=30
AZIMUTH=0 TILT=26 X=30 Y=60 Z=20
CONS=ATR-ROF ..
E4 =EXTERIOR-WALL H=14.5 W=60 AZ=270 Y=60 Z=20 ..
E5 =EXTERIOR-WALL LIKE E4 AZ=90 X=30 Y=0 ..
F1 =UNDERGROUND-FLOOR AREA=1800 CONS=BW2 ..
FRAME-A =EXTERIOR-WALL HEIGHT=29 WIDTH=30 Z=20 ..
WINDOW-A =WINDOW H=28.9 W=29.9 X=.05 Y=.05 GLASS-TYPE=GT2
OVERHANG-A=6 OH-B=0 OH-D=48.5 OH-W=42
OVERHANG-ANGLE=116 LEFT-FIN-A=0 L-F-B=0
L-F-H=30 L-F-D=3 RIGHT-FIN-A=0 R-F-B=0
R-F-H=30 R-F-D=3 ..
EXTERIOR-WALL LIKE FRAME-A HEIGHT=10.7 W=30 Z=9.3 ..
WINDOW LIKE WINDOW-A H=10.6 W=29.9 L-F-H=10.7
R-F-H=10.7 ..
ATZ2 =SPACE LIKE ATZ1 SOURCE-BTU/HR=0.0 Y=100 ..
ATROOF-2 =ROOF LIKE ATROOF-1 ..
EXTERIOR-WALL LIKE E4 ..
EXTERIOR-WALL LIKE E5 ..
UNDERGROUND-FLOOR LIKE F1 ..
FRAME-B =EXTERIOR-WALL LIKE FRAME-A ..
WINDOW-B =WINDOW LIKE WINDOW-A ..
EQUIP-RM =SPACE ZONE-TYPE=UNCONDITIONED
AREA=1200 VOLUME=17580 X=35 ..
EXTERIOR-WALL HEIGHT=20 WIDTH=30 ..
ROOF H=41.2 W=30 CONS=OFF-ROF
TILT=15 Z=9.3 X=30 Y=40 AZIMUTH=0 ..
INTERIOR-WALL AREA=279 CONS=WL3 NEXT-TO ATZ1 ..
UNDERGROUND-FLOOR AREA=1200 CONS=BW1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY (SS-A,SS-C,SS-J,SS-D) ..
$ HVAC SYSTEMS DESCRIPTION
$ DESIGN TEMPS ATRIUM COOLING 80F-SUMMER, 70F-WINTER HEATING 65F
$ OFFICE COOLING 76F HEATING 74F
$ SYSTEM TYPE THE ENTIRE BUILDING IS SERVED BY A WATER LOOP HEAT PUMP (HP)
$ SYSTEM. THE ATRIUM UNITS HAVE AN OUTSIDE AIR ECONOMIZER AND
$ PROVIDE MINIMUM VENTILATION AIR FOR ALL SPACES TO GIVE .25 AIR-
$ CHANGES/HOUR FOR THE ENTIRE BUILDING. IT IS ASSUMED THAT THE
$ OFFICE UNITS PULL THEIR OUTSIDE AIR FROM THE ATRIUM. THE
$ PERIMETER HP UNITS ARE FURNISHED WITH A WATER SIDE ECONOMIZER.
$ THE MINIMUM OUTSIDE AIR DAMPERS TO THE ATRIUM UNITS ARE HELD
$ CLOSED BETWEEN 9PM WHEN FANS ARE TURNED OFF UNTIL 9AM AT NORMAL
$ START. THE FANS OPERATE FROM 9AM TO 9PM MONDAY THRU SATURDAY,
$ AND ARE OFF ON SUNDAYS AND HOLIDAYS. THE FANS ARE ALLOWED TO
$ START AS EARLY AS 7AM TO PICK UP HEATING AND COOLING LOADS,
$ BUT ARE DELAYED AS LONG AS POSSIBLE. THE NIGHT SETBACK
$ TEMPERATURE IS 65F AND THE NIGHT SETUP TEMPERATURE IS 90F.
$ THE TEMPERATURE OF THE HP WATER LOOP IS MAINTAINED BETWEEN 55F
$ (BOILER SET POINT OF 60F) AND 90F (TOWER SETPOINT OF 85F),
$ BUT THE TOWER SETPOINT IS ALLOWED TO FLOAT TO LOWER
$ TEMPERATURES BASED UPON OUTDOOR WETBULB TEMPERATURE TO
$ IMPROVE THE EFFICIENCY OF THE HP UNITS. TOTAL SYSTEM VOLUME
$ INCLUDING A 7500 GALLON STORAGE TANK IS 10000 GALLONS.
$ FROM MAY 15 THRU OCT 15 A SEPARATE NIGHT VENTILATION SYSTEM
$ CAN CYCLE ON TO PROVIDE FREE OA COOLING OF THE ATRIUM, BUT ONLY
$ IF ITS SPACE TEMPERATURE IS ABOVE 76F. THE AIR SIDE CAPACITY
$ OF THE NIGHT VENTILATION SYSTEM IS TWICE AS LARGE AS THE HP
$ UNITS.
$ A SERVICE WATER HEAT PUMP IS LOCATED IN ATRIUM ATZ1. IT
$ SUPPLEMENTS THE DOMESTIC HOT WATER HEATER IN PLANT. THE
$ CAPACITY OF THE HEAT PUMP IS 24000 BTH/HR.
$ SCHEDULES
DAYS = WEEK-SCHEDULE (MON,SAT) (1,7)(0)(8,9)(-999)(10,21)(1)(22,24)(0)
(SUN,HOL) (1,24)(0) ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS ..
$ ATRIUM COOLING SCHEDULE
AT-C-WIN-HRS = DAY-SCHEDULE (1,24) (70) ..
AT-C-SUM-HRS = DAY-SCHEDULE (1,24) (80) ..
AT-C-WIN-DAYS = WEEK-SCHEDULE (ALL) AT-C-WIN-HRS ..
AT-C-SUM-DAYS = WEEK-SCHEDULE (ALL) AT-C-SUM-HRS ..
TCOOL1 = SCHEDULE THRU MAR 31 AT-C-WIN-DAYS
THRU OCT 31 AT-C-SUM-DAYS
THRU DEC 31 AT-C-WIN-DAYS ..
$ ATRIUM HEATING SCHEDULE
AT-HEAT-HRS = DAY-SCHEDULE (1,24) (65) ..
THEAT1 = SCHEDULE THRU DEC 31 (ALL) AT-HEAT-HRS ..
$ OFFICE COOLING SCHEDULE
OFF-1 = DAY-SCHEDULE (1,9)(90) (10,21)(76) (22,24)(90) ..
OFF-2 = DAY-SCHEDULE (1,24) (90) ..
TCOOL2 = SCHEDULE THRU DEC 31 (MON,SAT) OFF-1 (SUN,HOL) OFF-2 ..
$ OFFICE HEATING SCHEDULE
OFF-3 = DAY-SCHEDULE (1,9)(65) (10,21)(74) (22,24)(65) ..
OFF-4 = DAY-SCHEDULE (1,24)(65) ..
THEAT2 = SCHEDULE THRU DEC 31 (MON,SAT) OFF-3 (SUN,HOL) OFF-4 ..
$ NIGHT VENTILATION SCHEDULES
VENT-T = SCHEDULE THRU DEC 31 (ALL) (1,24) (76) ..
VENT-ON-OFF = SCHEDULE THRU MAY 15 (ALL) (1,24) (0)
THRU OCT 15 (ALL) (1,24) (1)
THRU DEC 31 (ALL) (1,24) (0) ..
MIN-OA = SCHEDULE THRU DEC 31 (ALL) (1,9)(0) (10,21)(-999) (22,24)(0) ..
$ ZONE DESCRIPTION
ENV-ATR = ZONE-CONTROL D-H-T 70 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL1
T-TYPE PROPORTIONAL ..
ENV-OFF = ZONE-CONTROL D-H-T 74 D-C-T 74 H-T-SCH THEAT2 C-T-SCH TCOOL2
T-TYPE PROPORTIONAL ..
ATZ1 = ZONE Z-C ENV-ATR OUTSIDE-AIR-CFM 1665 ..
ATZ2 = ZONE LIKE ATZ1 ..
EQUIP-RM = ZONE ZONE-TYPE=UNCONDITIONED ..
BZ1 = ZONE Z-C ENV-OFF ZONE-REPORTS = NO ..
BZ2 = ZONE LIKE BZ1 ..
BZ3 = ZONE LIKE BZ1 ..
TZ1 = ZONE LIKE BZ1 ..
TZ2 = ZONE LIKE BZ1 ..
TZ3 = ZONE LIKE BZ1 ..
IZ1 = ZONE LIKE BZ1 ..
IZ2 = ZONE LIKE BZ1 ..
HP-SYS-CORE = SYSTEM SYSTEM-TYPE=HP MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=2.5 SUPPLY-EFF=.45
OA-CONTROL = TEMP ECONO-LIMIT-T = 68
FAN-SCHEDULE=AHU-SCHED
FLUID-VOLUME = 30
MIN-AIR-SCH = MIN-OA
SHW-HP-SIZE=24000 SHW-HP-SOURCE=ZONE
SHW-HP-ZONE=ATZ1
ZONE-NAMES=(ATZ1,ATZ2,EQUIP-RM)
SIZING-RATIO=1.5 ..
HP-SYS-PERM = SYSTEM SYSTEM-TYPE = HP MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=2.5 SUPPLY-EFF=.55
FLUID-VOLUME=30
FAN-SCHEDULE=AHU-SCHED
ZONE-NAMES=(BZ1,BZ2,BZ3,TZ1,TZ2,
TZ3,IZ1,IZ2) ..
WLHP = PLANT-ASSIGNMENT
SYSTEM-NAMES = (HP-SYS-CORE,HP-SYS-PERM)
HP-LOOP-HEATING = FROM-SYSTEMS
HP-LOOP-COOLING = FROM-SYSTEMS
BOILER-TYPE = FUEL-BOILER
BOILER-SET-POINT= 60
TWR-SETPT-CTRL = WETBULB-RESET
TWR-CAP-CTRL = TWO-SPEED-FAN
MIN-TWR-WTR-T = 61
TWR-DESIGN-WETBULB = 78
CIRC-PUMP-SCH = AHU-SCHED
CIRC-PUMP-TYPE = VARIABLE-FLOW
PLANT-REPORTS = YES
DHW-SIZE = 0
DHW-GAL/MIN = .222
DHW-SCH = OCCUP ..
TWR-FLOAT = SCHEDULE THRU MAY 15 (ALL) (1,24)(85)
THRU OCT 15 (ALL) (1,24)(75)
THRU DEC 31 (ALL) (1,24)(85) ..
OC1 =DAY-SCHEDULE (1,9) (0) (10,12) (1) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
OC2 =DAY-SCHEDULE (1,24) (.2) ..
OCCUPANCY =WEEK-SCHEDULE (MON,TUE) OC1 (WED) OC2
(THU,SAT) OC1 (SUN,HOL) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 OCCUPANCY ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
WLHP = PLANT-ASSIGNMENT ..
PLANT-REPORT SUMMARY (PS-A,PS-D,BEPS) ..
$ PLANT DESCRIPTION
DHW = PLANT-EQUIPMENT TYPE=DHW-HEATER SIZE -999 I-N 1 ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
DIAGNOSTIC WARNINGS ..
ECONOMICS-REPORT SUMMARY (ES-D,ES-E) ..
$ ENERGY CHARGE DESCRIPTION
$ THE ELECTRIC RATE IS TIME-OF-USE WITH SEPARATE SUMMER/WINTER MINIMUM
$ DEMAND CHARGES. IN ADDITION IT HAS S/W DEMAND CHARGES THAT APPLY ONLY TO THE
$ ON-PEAK HOURS. THE TWO DEMANDS ARE ADDITIVE, APPLY TO THE HIGHEST PEAK, BUT
$ ONLY THE ON-PEAK CARRIES A RATCHET OF 90%. THE ENERGY CHARGES ARE
$ DOLLARS/KWH FOR THREE PERIODS (I.E. ON-PEAK, INTERMEDIATE-PEAK, AND OFF-PEAK).
$ THE FUEL FOR THE HOT WATER GENERATOR SIMULATED IN SYSTEMS PLUS THE DOMESTIC
$ HOT-WATER HEATER IS NATURAL-GAS ..
ELEC-COST = UTILITY-RATE RESOURCE = ELECTRICITY
MIN-MON-CHGS = (186)
DEMAND-CHGS = (2.25,2.25,2.25,2.25, 2.58,
2.58,2.58,2.58,2.58,2.58,2.25)
BLOCK-CHARGES = (SUM-P-DEM,WIN-P-DEM)
ENERGY-CHG-SCH = TOU-SCH ..
TOU-SCH = SCHEDULE THRU APR 30 (WD) (1,8)(.0324)
(9,12)(.0354)
(13,18)(.0394)
(19,21)(.0354)
(22,24)(.0354)
(WEH)(1,24)(.0354)
THRU OCT 31 (WD) (1,8)(.0374)
(9,12)(.0394)
(13,18)(.0444)
(19,21)(.0394)
(22,24)(.0374)
(WEH)(1,24)(.0374)
THRU DEC 31 (WD) (1,8)(.0324)
(9,12)(.0354)
(13,18)(.0394)
(19,21)(.0354)
(22,24)(.0354)
(WEH)(1,24)(.0354) ..
SUM-P-DEM = BLOCK-CHARGE BLOCK-SCH = DEM-SCH
SCH-FLAG = 2
BLOCK1-TYPE = DEMAND
BLOCK1-DATA = (1,7.00)
DEMAND-RATCHETS = (SUM-RATCH) ..
WIN-P-DEM = BLOCK-CHARGE BLOCK-SCH = DEM-SCH
SCH-FLAG = 1
BLOCK1-TYPE = DEMAND
BLOCK1-DATA = (1,6.50)
DEMAND-RATCHETS = (SUM-RATCH) ..
SUM-RATCH = RATCHET NUM-MONTHS = 12
RATCHET-SCH = DEM-SCH
SCH-FLAG = 2
TYPE = HIGHEST-PEAK
FRACTION = .90 ..
DEM-SCH = SCHEDULE THRU APR 30 (WD) (1,12) (0)
(13,18)(1)
(19,24)(0)
(WEH) (1,24) (0)
THRU OCT 31 (WD) (1,12) (0)
(13,18)(2)
(19,24)(0)
(WEH) (1,24) (0)
THRU DEC 31 (WD) (1,12) (0)
(13,18)(1)
(19,24)(0)
(WEH) (1,24) (0) ..
GAS-COST = UTILITY-RATE RESOURCE = NATURAL-GAS
ENERGY-CHG = .90 ..
END ..
COMPUTE ECONOMICS ..
INPUT LOADS ..
|
Products and Solutions 
