INPUT LOADS ..
TITLE LINE-1 * MEDICAL OFFICE BUILDING, CHICAGO*
LINE-2 * WATER LOOP HEAT PUMP WITH STORAGE *
LINE-3 * SAMP3.INP RUN 1 * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD JAN 1 1988 THRU DEC 31 1988 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
LOADS-REPORT SUMMARY=(LS-B,LS-C,LS-D) ..
$ BUILDING DESCRIPTION
$ STRUCTURE REINFORCED CONCRETE CONSTRUCTION WITH 4IN CONCRETE FLOORS AND ROOF
$ 10FT FLOOR TO FLOOR HEIGHT, TWO STORIES HIGH. RETURN AIR PLENUMS
$ ARE NOT DEFINED.
$ WALLS USING CODE WORDS FROM THE DOE-2 LIBRARY (REFERENCE MANUAL PART 2)
$ AND STARTING WITH THE OUTSIDE SURFACE AND MOVING INWARD:
$ 2IN PRECAST CONCRETE PANEL (CC03); 2IN POLYSTRENE INSULATION
$ R-8 (IN35); 3IN AIRSPACE (AL21); 5/8IN GYPSUM BOARD (GP04);
$ 3/4IN FINISH PLASTER.
$ ATRIUM ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 6IN CONCRETE (CC04); INSIDE FILM RESISTANCE .76
$ OFFICE ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 2 FT AIR SPACE (AL33); 3/4IN LAY-IN ACCOUSTIC TILE (AC03);
$ INSIDE-FILM-RESISTANCE .76.
$ FLOORS FIRST FL IS SLAB-ON-GRADE EFFECTIVE U-VALUE OF ENTIRE AREA .05.
$ WINDOWS OFFICE AREA 4FT HIGH AND FULL WIDTH OF EACH WALL, EXCEPT SOUTH
$ WALL WHERE THERE ARE NO WINDOWS. GLASS IS DOUBLE PANE TINTED
$ WITH A SOLAR TRANSMITTANCE OF .53. WINDOWS HAVE INSIDE DRAPES
$ THAT HAVE A PROBABILITY OF.7 OF BEING PULLED WHEN TRANSMITTED
$ DIRECT RADIATION IS GREATER THAN 40 BTUH. DRAPES ARE THEN REOPEN-
$ ED WITH A PROBABILITY OF .2 WHENEVER SOLAR DROPS BELOW 40BTUH.
$ ATRIUM GLASS IS THE SAME AS OFFICE GLASS EXCEPT THAT IT DOES NOT
$ HAVE DRAPES. THERE ARE TWO MAIN SECTIONS OF GLASS 29' WIDE BY
$ 30' HIGH WITH OVERHANGS AND SIDE FINS. NOTICE THAT THE SKETCH
$ OF THE BUILDING INDICATES A LARGE OVERHANG WHICH WOULD BE VERY
$ DIFFICULT TO BUILD. THIS WAS THE WAY IT WAS SIMULATED AS THIS
$ METHOD IS EQUIVALENT TO MULTIPLE SURFACES THAT PROVIDE THE SAME
$ SHADING GEOMETRY.
$ INTERIORS CEILINGS ARE SIMULATED AS PART OF THE ROOF STRUCTURE ON THE TOP
$ FLOOR. PARTITIONS SIMULATE A GLASS WALL BETWEEN ATRIUM AND
$ OFFICE SPACES, BUT WALLS BETWEEN INTERIOR AND EXTERIOR OFFICES
$ ARE NOT DEFINED. WALLS BETWEEN THE EQUIPMENT ROOM AND OFFICES
$ HAVE A U-VALUE OF .28.
$ SPACE LOADS LIGHTING IS RECESSED FLUORSCENT NON VENTED AT 1.5 WATTS/SQFT IN
$ THE OFFICES AND 1 WATT/SQFT IN THE ATRIUM.
$ PEOPLE IN OFFICES IS CALCULATED BY DOE-2 AT 150SQFT/PERSON.
$ INFILTRATION IS SET AT .2 AIRCHANGES/HR WHEN FANS ARE OFF AND AT
$ .1 AIRCHANGE WHEN FANS ARE ON.
$ EQUIPMENT IN OFFICES IS SET AT 1 WATTS/SQFT
$ CONSTRUCTIONS
ROOF-O =LAYERS MAT=(BR01,IN76,CC03,AL33,AC03) I-F-R=.76 ..
ROOF-A =LAYERS MAT=(BR01,IN76,CC04) I-F-R .76 ..
OFF-ROF =CONSTRUCTION LAYERS ROOF-O ..
ATR-ROF =CONSTRUCTION LAYERS ROOF-A ..
WALL-1 =LAYERS MAT=(CC33,IN35,AL21,GP04,GP04) ..
WL1 =CONSTRUCTION LAYERS=WALL-1 ..
BW1 =CONSTRUCTION U=.05 ..
BW2 =CONSTRUCTION U=.0001 ..
WL2 =CONSTRUCTION U=1.05 $ ATRIUM GLASS PARTITIONS $ ..
WL3 =CONSTRUCTION U=.28 $ INTERIOR PARTITIONS $ ..
$ GLASS DESCRIPTION
GT1 =GLASS-TYPE GLASS-TYPE-CODE 5 PANES 2 ..
GT2 =GLASS-TYPE G-T-C 5 PANES 2 ..
$ SCHEDULES
OC1 =DAY-SCHEDULE (1,9) (0) (10,12) (1) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
OC2 =DAY-SCHEDULE (1,24) (.2) ..
OCCUPANCY =WEEK-SCHEDULE (MON,TUE) OC1 (WED) OC2
(THU,SAT) OC1 (SUN,HOL) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 OCCUPANCY ..
L1 =DAY-SCHEDULE (1,6) (.2) (7,12) (.9) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
L2 =DAY-SCHEDULE (1,24) (.2) ..
LIGHTS =WEEK-SCHEDULE (MON,TUE) L1 (WED) L2
(THU,SAT) L1 (SUN,HOL) L2 ..
LT1 =SCHEDULE THRU DEC 31 LIGHTS ..
ES1 =DAY-SCHEDULE (1,9) (0) (10,21) (.9) (22,24) (.4) ..
ES2 =DAY-SCHEDULE (1,9) (0) (10,24) (.4) ..
EQUIPMENT =WEEK-SCHEDULE (MON,TUE) ES1 (WED) ES2
(THU,SAT) ES1 (SUN,HOL) ES2 ..
EQ1 =SCHEDULE THRU DEC 31 EQUIPMENT ..
I1 =DAY-SCHEDULE (1,9) (1) (10,21) (.5) (22,24) (1) ..
INFILTRAT =WEEK-SCHEDULE (ALL) I1 ..
INF1 =SCHEDULE THRU DEC 31 INFILTRAT ..
SHADE-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.6) ..
COND-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.90) ..
CLOSE-SHADE =SCHEDULE THRU DEC 31 (ALL) (1,24) (40) ..
REOPEN-PROB =SCHEDULE THRU DEC 31 (ALL) (1,24) (.2) ..
$ BUILDING SHADE BY ANOTHER BUILDING
$ FOR PURPOSE OF DEMONSTRATION ASSUME THAT THERE IS ANOTHER BUILDING IN
$ ALIGNMENT WITH THE MEDICAL BLDG BUT 150FT TO THE WEST. IT IS 170FT TALL
$ AND 110FT WIDE. THE INPUT TO REPRESENT THIS AS A SHADING SURFACE IS:
BUILDING-SHADE H=170 W=110 AZ=90 TILT=90 X=-150 ..
$ SET DEFAULTS
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=10 AZIMUTH=180
CONSTRUCTION=WL1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4 Y=4 GLASS-TYPE=GT1
MAX-SOLAR-SCH=CLOSE-SHADE SUN-CTRL-PROB .7
WIN-SHADE-TYPE=MOVABLE-INTERIOR
SHADING-SCHEDULE=SHADE-MULT
CONDUCT-SCHEDULE=COND-MULT
OPEN-SHADE-SCH=REOPEN-PROB ..
$ SPACE DESCRIPTION
OFFICE =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=70
EQUIPMENT-W/SQFT=1 EQUIP-SCHEDULE=EQ1
LIGHTING-W/SQFT=1.5 LIGHTING-SCHEDULE=LT1
INF-METHOD=AIR-CHANGE AIR-CHANGES/HR=.2
LIGHTING-TYPE=SUS-FLUOR
PEOPLE-HG-LAT=200 PEOPLE-HG-SENS=250
PEOPLE-SCHEDULE=OCCUP AREA/PERSON=150 ..
ATRIUM =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=100
LIGHTING-SCHEDULE=LT1
LIGHTING-TYPE=INCAND
LIGHTING-W/SQFT=1
INF-SCHEDULE=INF1 AIR-CHANGES/HR=.2
INF-METHOD=AIR-CHANGE ..
BZ1 =SPACE S-C=OFFICE AREA=3230 VOLUME=29070
AZ=90 Y=200 ..
E1 =EXTERIOR-WALL WIDTH=200 ..
W1 =WINDOW WIDTH=200 ..
E1S =EXTERIOR-WALL W=17 AZ=90 X=200 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
BZ2 =SPACE S-C=OFFICE AREA=1660 VOLUME=14940
AZ=180 X=100 Y=200 ..
E2 =EXTERIOR-WALL WIDTH=100 ..
W2 =WINDOW WIDTH=100 ..
UNDERGROUND-FLOOR AREA=1660 CONS=BW1 ..
BZ3 =SPACE LIKE BZ1 AZ=-90 X=100 Y=0 ..
E3 =EXTERIOR-WALL LIKE E1 ..
W3 =WINDOW LIKE W1 ..
E3S =EXTERIOR-WALL W=17 AZ=270 Y=17 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
TZ1 =SPACE LIKE BZ1 Z=10 ..
R1 =ROOF H=17 W=200 AZ=180 TILT=0 Z=10
CONS=OFF-ROF ..
EXTERIOR-WALL LIKE E1 ..
WINDOW LIKE W1 ..
EXTERIOR-WALL LIKE E1S ..
TZ2 =SPACE LIKE BZ2 Z=10 ..
ROOF LIKE R1 H=20 W=83 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE BZ3 Z=10 ..
ROOF LIKE R1 H=17 W=180 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
EXTERIOR-WALL LIKE E3S ..
IZ1 =SPACE S-C=OFFICE AREA=3540 VOLUME=70800
AZ=90 X=17 Y=180 ..
IN1 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ1 CONS=WL2 ..
IN2 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ2 CONS=WL2 ..
IN3 =INTERIOR-WALL AREA=586 NEXT-TO EQUIP-RM CONS=WL3 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 Y=18 Z=20 ..
EXTERIOR-WALL H=20 W=18 AZ=90 X=180 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
IZ2 =SPACE LIKE IZ1 AZ=-90 X=83 Y=0 ..
INTERIOR-WALL LIKE IN1 NEXT-TO ATZ1 ..
INTERIOR-WALL LIKE IN2 NEXT-TO ATZ2 ..
INTERIOR-WALL LIKE IN3 ..
EXTERIOR-WALL H=20 W=18 AZ=270 Y=18 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 X=160 Y=18 Z=20 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
ATZ1 =SPACE S-C=ATRIUM AREA=1800 VOLUME=16200
X=35 Y=40
SOURCE-TYPE = HOT-WATER
SOURCE-BTU/HR = 30000
SOURCE-SENSIBLE = 0.0
SOURCE-SCHEDULE = OCCUP ..
ATROOF-1 =ROOF HEIGHT=66.6 WIDTH=30
AZIMUTH=0 TILT=26 X=30 Y=60 Z=20
CONS=ATR-ROF ..
E4 =EXTERIOR-WALL H=14.5 W=60 AZ=270 Y=60 Z=20 ..
E5 =EXTERIOR-WALL LIKE E4 AZ=90 X=30 Y=0 ..
F1 =UNDERGROUND-FLOOR AREA=1800 CONS=BW2 ..
FRAME-A =EXTERIOR-WALL HEIGHT=29 WIDTH=30 Z=20 ..
WINDOW-A =WINDOW H=28.9 W=29.9 X=.05 Y=.05 GLASS-TYPE=GT2
OVERHANG-A=6 OH-B=0 OH-D=48.5 OH-W=42
OVERHANG-ANGLE=116 LEFT-FIN-A=0 L-F-B=0
L-F-H=30 L-F-D=3 RIGHT-FIN-A=0 R-F-B=0
R-F-H=30 R-F-D=3 ..
EXTERIOR-WALL LIKE FRAME-A HEIGHT=10.7 W=30 Z=9.3 ..
WINDOW LIKE WINDOW-A H=10.6 W=29.9 L-F-H=10.7
R-F-H=10.7 ..
ATZ2 =SPACE LIKE ATZ1 SOURCE-BTU/HR=0.0 Y=100 ..
ATROOF-2 =ROOF LIKE ATROOF-1 ..
EXTERIOR-WALL LIKE E4 ..
EXTERIOR-WALL LIKE E5 ..
UNDERGROUND-FLOOR LIKE F1 ..
FRAME-B =EXTERIOR-WALL LIKE FRAME-A ..
WINDOW-B =WINDOW LIKE WINDOW-A ..
EQUIP-RM =SPACE ZONE-TYPE=UNCONDITIONED
AREA=1200 VOLUME=17580 X=35 ..
EXTERIOR-WALL HEIGHT=20 WIDTH=30 ..
ROOF H=41.2 W=30 CONS=OFF-ROF
TILT=15 Z=9.3 X=30 Y=40 AZIMUTH=0 ..
INTERIOR-WALL AREA=279 CONS=WL3 NEXT-TO ATZ1 ..
UNDERGROUND-FLOOR AREA=1200 CONS=BW1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY (SS-A,SS-C,SS-J,SS-D) ..
$ HVAC SYSTEMS DESCRIPTION
$ DESIGN TEMPS ATRIUM COOLING 80F-SUMMER, 70F-WINTER HEATING 65F
$ OFFICE COOLING 76F HEATING 74F
$ SYSTEM TYPE THE ENTIRE BUILDING IS SERVED BY A WATER LOOP HEAT PUMP (HP)
$ SYSTEM. THE ATRIUM UNITS HAVE AN OUTSIDE AIR ECONOMIZER AND
$ PROVIDE MINIMUM VENTILATION AIR FOR ALL SPACES TO GIVE .25 AIR-
$ CHANGES/HOUR FOR THE ENTIRE BUILDING. IT IS ASSUMED THAT THE
$ OFFICE UNITS PULL THEIR OUTSIDE AIR FROM THE ATRIUM. THE
$ PERIMETER HP UNITS ARE FURNISHED WITH A WATER SIDE ECONOMIZER.
$ THE MINIMUM OUTSIDE AIR DAMPERS TO THE ATRIUM UNITS ARE HELD
$ CLOSED BETWEEN 9PM WHEN FANS ARE TURNED OFF UNTIL 9AM AT NORMAL
$ START. THE FANS OPERATE FROM 9AM TO 9PM MONDAY THRU SATURDAY,
$ AND ARE OFF ON SUNDAYS AND HOLIDAYS. THE FANS ARE ALLOWED TO
$ START AS EARLY AS 7AM TO PICK UP HEATING AND COOLING LOADS,
$ BUT ARE DELAYED AS LONG AS POSSIBLE. THE NIGHT SETBACK
$ TEMPERATURE IS 65F AND THE NIGHT SETUP TEMPERATURE IS 90F.
$ THE TEMPERATURE OF THE HP WATER LOOP IS MAINTAINED BETWEEN 55F
$ (BOILER SET POINT OF 60F) AND 90F (TOWER SETPOINT OF 85F),
$ BUT THE TOWER SETPOINT IS ALLOWED TO FLOAT TO LOWER
$ TEMPERATURES BASED UPON OUTDOOR WETBULB TEMPERATURE TO
$ IMPROVE THE EFFICIENCY OF THE HP UNITS. TOTAL SYSTEM VOLUME
$ INCLUDING A 7500 GALLON STORAGE TANK IS 10000 GALLONS.
$ FROM MAY 15 THRU OCT 15 A SEPARATE NIGHT VENTILATION SYSTEM
$ CAN CYCLE ON TO PROVIDE FREE OA COOLING OF THE ATRIUM, BUT ONLY
$ IF ITS SPACE TEMPERATURE IS ABOVE 76F. THE AIR SIDE CAPACITY
$ OF THE NIGHT VENTILATION SYSTEM IS TWICE AS LARGE AS THE HP
$ UNITS.
$ A SERVICE WATER HEAT PUMP IS LOCATED IN ATRIUM ATZ1. IT
$ SUPPLEMENTS THE DOMESTIC HOT WATER HEATER IN PLANT. THE
$ CAPACITY OF THE HEAT PUMP IS 24000 BTH/HR.
$ SCHEDULES
DAYS = WEEK-SCHEDULE (MON,SAT) (1,7)(0)(8,9)(-999)(10,21)(1)(22,24)(0)
(SUN,HOL) (1,24)(0) ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS ..
$ ATRIUM COOLING SCHEDULE
AT-C-WIN-HRS = DAY-SCHEDULE (1,24) (70) ..
AT-C-SUM-HRS = DAY-SCHEDULE (1,24) (80) ..
AT-C-WIN-DAYS = WEEK-SCHEDULE (ALL) AT-C-WIN-HRS ..
AT-C-SUM-DAYS = WEEK-SCHEDULE (ALL) AT-C-SUM-HRS ..
TCOOL1 = SCHEDULE THRU MAR 31 AT-C-WIN-DAYS
THRU OCT 31 AT-C-SUM-DAYS
THRU DEC 31 AT-C-WIN-DAYS ..
$ ATRIUM HEATING SCHEDULE
AT-HEAT-HRS = DAY-SCHEDULE (1,24) (65) ..
THEAT1 = SCHEDULE THRU DEC 31 (ALL) AT-HEAT-HRS ..
$ OFFICE COOLING SCHEDULE
OFF-1 = DAY-SCHEDULE (1,9)(90) (10,21)(76) (22,24)(90) ..
OFF-2 = DAY-SCHEDULE (1,24) (90) ..
TCOOL2 = SCHEDULE THRU DEC 31 (MON,SAT) OFF-1 (SUN,HOL) OFF-2 ..
$ OFFICE HEATING SCHEDULE
OFF-3 = DAY-SCHEDULE (1,9)(65) (10,21)(74) (22,24)(65) ..
OFF-4 = DAY-SCHEDULE (1,24)(65) ..
THEAT2 = SCHEDULE THRU DEC 31 (MON,SAT) OFF-3 (SUN,HOL) OFF-4 ..
$ NIGHT VENTILATION SCHEDULES
VENT-T = SCHEDULE THRU DEC 31 (ALL) (1,24) (76) ..
VENT-ON-OFF = SCHEDULE THRU MAY 15 (ALL) (1,24) (0)
THRU OCT 15 (ALL) (1,24) (1)
THRU DEC 31 (ALL) (1,24) (0) ..
MIN-OA = SCHEDULE THRU DEC 31 (ALL) (1,9)(0) (10,21)(-999) (22,24)(0) ..
$ ZONE DESCRIPTION
ENV-ATR = ZONE-CONTROL D-H-T 70 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL1
T-TYPE PROPORTIONAL ..
ENV-OFF = ZONE-CONTROL D-H-T 74 D-C-T 74 H-T-SCH THEAT2 C-T-SCH TCOOL2
T-TYPE PROPORTIONAL ..
ATZ1 = ZONE Z-C ENV-ATR OUTSIDE-AIR-CFM 1665 ..
ATZ2 = ZONE LIKE ATZ1 ..
EQUIP-RM = ZONE ZONE-TYPE=UNCONDITIONED ..
BZ1 = ZONE Z-C ENV-OFF ZONE-REPORTS = NO ..
BZ2 = ZONE LIKE BZ1 ..
BZ3 = ZONE LIKE BZ1 ..
TZ1 = ZONE LIKE BZ1 ..
TZ2 = ZONE LIKE BZ1 ..
TZ3 = ZONE LIKE BZ1 ..
IZ1 = ZONE LIKE BZ1 ..
IZ2 = ZONE LIKE BZ1 ..
HP-SYS-CORE = SYSTEM SYSTEM-TYPE=HP MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=2.5 SUPPLY-EFF=.45
OA-CONTROL = TEMP ECONO-LIMIT-T = 68
FAN-SCHEDULE=AHU-SCHED
FLUID-VOLUME = 30
MIN-AIR-SCH = MIN-OA
SHW-HP-SIZE=24000 SHW-HP-SOURCE=ZONE
SHW-HP-ZONE=ATZ1
ZONE-NAMES=(ATZ1,ATZ2,EQUIP-RM)
SIZING-RATIO=1.5 ..
HP-SYS-PERM = SYSTEM SYSTEM-TYPE = HP MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=2.5 SUPPLY-EFF=.55
FLUID-VOLUME=30
FAN-SCHEDULE=AHU-SCHED
ZONE-NAMES=(BZ1,BZ2,BZ3,TZ1,TZ2,
TZ3,IZ1,IZ2) ..
WLHP = PLANT-ASSIGNMENT
SYSTEM-NAMES = (HP-SYS-CORE,HP-SYS-PERM)
HP-LOOP-HEATING = FROM-SYSTEMS
HP-LOOP-COOLING = FROM-SYSTEMS
BOILER-TYPE = FUEL-BOILER
BOILER-SET-POINT= 60
TWR-SETPT-CTRL = WETBULB-RESET
TWR-CAP-CTRL = TWO-SPEED-FAN
MIN-TWR-WTR-T = 61
TWR-DESIGN-WETBULB = 78
CIRC-PUMP-SCH = AHU-SCHED
CIRC-PUMP-TYPE = VARIABLE-FLOW
PLANT-REPORTS = YES
DHW-SIZE = 0
DHW-GAL/MIN = .222
DHW-SCH = OCCUP ..
TWR-FLOAT = SCHEDULE THRU MAY 15 (ALL) (1,24)(85)
THRU OCT 15 (ALL) (1,24)(75)
THRU DEC 31 (ALL) (1,24)(85) ..
OC1 =DAY-SCHEDULE (1,9) (0) (10,12) (1) (13,14) (.8,.4)
(15,18) (.7) (19,21) (.4) (22,24) (.2) ..
OC2 =DAY-SCHEDULE (1,24) (.2) ..
OCCUPANCY =WEEK-SCHEDULE (MON,TUE) OC1 (WED) OC2
(THU,SAT) OC1 (SUN,HOL) OC2 ..
OCCUP =SCHEDULE THRU DEC 31 OCCUPANCY ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
WLHP = PLANT-ASSIGNMENT ..
PLANT-REPORT SUMMARY (PS-A,PS-D,BEPS) ..
$ PLANT DESCRIPTION
DHW = PLANT-EQUIPMENT TYPE=DHW-HEATER SIZE -999 I-N 1 ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
DIAGNOSTIC WARNINGS ..
ECONOMICS-REPORT SUMMARY (ES-D,ES-E) ..
$ ENERGY CHARGE DESCRIPTION
$ THE ELECTRIC RATE IS TIME-OF-USE WITH SEPARATE SUMMER/WINTER MINIMUM
$ DEMAND CHARGES. IN ADDITION IT HAS S/W DEMAND CHARGES THAT APPLY ONLY TO THE
$ ON-PEAK HOURS. THE TWO DEMANDS ARE ADDITIVE, APPLY TO THE HIGHEST PEAK, BUT
$ ONLY THE ON-PEAK CARRIES A RATCHET OF 90%. THE ENERGY CHARGES ARE
$ DOLLARS/KWH FOR THREE PERIODS (I.E. ON-PEAK, INTERMEDIATE-PEAK, AND OFF-PEAK).
$ THE FUEL FOR THE HOT WATER GENERATOR SIMULATED IN SYSTEMS PLUS THE DOMESTIC
$ HOT-WATER HEATER IS NATURAL-GAS ..
ELEC-COST = UTILITY-RATE RESOURCE = ELECTRICITY
MIN-MON-CHGS = (186)
DEMAND-CHGS = (2.25,2.25,2.25,2.25, 2.58,
2.58,2.58,2.58,2.58,2.58,2.25)
BLOCK-CHARGES = (SUM-P-DEM,WIN-P-DEM)
ENERGY-CHG-SCH = TOU-SCH ..
TOU-SCH = SCHEDULE THRU APR 30 (WD) (1,8)(.0324)
(9,12)(.0354)
(13,18)(.0394)
(19,21)(.0354)
(22,24)(.0354)
(WEH)(1,24)(.0354)
THRU OCT 31 (WD) (1,8)(.0374)
(9,12)(.0394)
(13,18)(.0444)
(19,21)(.0394)
(22,24)(.0374)
(WEH)(1,24)(.0374)
THRU DEC 31 (WD) (1,8)(.0324)
(9,12)(.0354)
(13,18)(.0394)
(19,21)(.0354)
(22,24)(.0354)
(WEH)(1,24)(.0354) ..
SUM-P-DEM = BLOCK-CHARGE BLOCK-SCH = DEM-SCH
SCH-FLAG = 2
BLOCK1-TYPE = DEMAND
BLOCK1-DATA = (1,7.00)
DEMAND-RATCHETS = (SUM-RATCH) ..
WIN-P-DEM = BLOCK-CHARGE BLOCK-SCH = DEM-SCH
SCH-FLAG = 1
BLOCK1-TYPE = DEMAND
BLOCK1-DATA = (1,6.50)
DEMAND-RATCHETS = (SUM-RATCH) ..
SUM-RATCH = RATCHET NUM-MONTHS = 12
RATCHET-SCH = DEM-SCH
SCH-FLAG = 2
TYPE = HIGHEST-PEAK
FRACTION = .90 ..
DEM-SCH = SCHEDULE THRU APR 30 (WD) (1,12) (0)
(13,18)(1)
(19,24)(0)
(WEH) (1,24) (0)
THRU OCT 31 (WD) (1,12) (0)
(13,18)(2)
(19,24)(0)
(WEH) (1,24) (0)
THRU DEC 31 (WD) (1,12) (0)
(13,18)(1)
(19,24)(0)
(WEH) (1,24) (0) ..
GAS-COST = UTILITY-RATE RESOURCE = NATURAL-GAS
ENERGY-CHG = .90 ..
END ..
COMPUTE ECONOMICS ..
INPUT LOADS ..
TITLE LINE-1 * OFFICE BUILDING & FLOWER SHOP, CHICAGO*
LINE-2 * VAV SYSTEM IN OFFICE & SZRH IN SHOP *
LINE-3 * DIRECT FIRED ABSORPTION W/ HWG *
LINE-4 * SAMP3.INP RUN 2 * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD JAN 1 1988 THRU DEC 31 1988 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
LOADS-REPORT SUMMARY=(LS-D) ..
$ BUILDING DESCRIPTION
$ THE MEDICAL OFFICE BUILDING ABOVE HAS BEEN REMODELED WITH
$ DIFFERENT USAGES TO DEMONSTRATE NEW FEATURES OF DOE2.1D.
$ STRUCTURE REINFORCED CONCRETE CONSTRUCTION WITH 4IN CONCRETE FLOORS AND ROOF
$ 10FT FLOOR TO FLOOR HEIGHT, TWO STORIES HIGH. RETURN AIR PLENUMS
$ ARE NOT DEFINED.
$ WALLS USING CODE WORDS FROM THE DOE-2 LIBRARY (REFERENCE MANUAL PART 2)
$ AND STARTING WITH THE OUTSIDE SURFACE AND MOVING INWARD:
$ 2IN PRECAST CONCRETE PANEL (CC03); 2IN POLYSTRENE INSULATION
$ R-8 (IN35); 3IN AIRSPACE (AL21); 5/8IN GYPSUM BOARD (GP04);
$ 3/4IN FINISH PLASTER.
$ ATRIUM ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 6IN CONCRETE (CC04); INSIDE FILM RESISTANCE .76
$ OFFICE ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 2 FT AIR SPACE (AL33); 3/4IN LAY-IN ACCOUSTIC TILE (AC03);
$ INSIDE-FILM-RESISTANCE .76.
$ FLOORS FIRST FL IS SLAB-ON-GRADE EFFECTIVE U-VALUE OF ENTIRE AREA .05.
$ WINDOWS OFFICE AREA 4FT HIGH AND FULL WIDTH OF EACH WALL, EXCEPT SOUTH
$ WALL WHERE THERE ARE NO WINDOWS. GLASS IS DOUBLE PANE TINTED
$ WITH A SOLAR TRANSMITTANCE OF .53. WINDOWS HAVE INSIDE DRAPES
$ THAT HAVE A PROBABILITY OF.7 OF BEING PULLED WHEN TRANSMITTED
$ DIRECT RADIATION IS GREATER THAN 40 BTUH. DRAPES ARE THEN REOPEN-
$ ED WITH A PROBABILITY OF .2 WHENEVER SOLAR DROPS BELOW 40BTUH.
$ ATRIUM GLASS IS THE SAME AS OFFICE GLASS EXCEPT THAT IT DOES NOT
$ HAVE DRAPES. THERE ARE TWO MAIN SECTIONS OF GLASS 29' WIDE BY
$ 30' HIGH WITH OVERHANGS AND SIDE FINS. NOTICE THAT THE SKETCH
$ OF THE BUILDING INDICATES A LARGE OVERHANG WHICH WOULD BE VERY
$ DIFFICULT TO BUILD. THIS WAS THE WAY IT WAS SIMULATED AS THIS
$ METHOD IS EQUIVALENT TO MULTIPLE SURFACES THAT PROVIDE THE SAME
$ SHADING GEOMETRY.
$ INTERIORS CEILINGS ARE SIMULATED AS PART OF THE ROOF STRUCTURE ON THE TOP
$ FLOOR. PARTITIONS SIMULATE A GLASS WALL BETWEEN ATRIUM AND
$ OFFICE SPACES, BUT WALLS BETWEEN INTERIOR AND EXTERIOR OFFICES
$ ARE NOT DEFINED. WALLS BETWEEN THE EQUIPMENT ROOM AND OFFICES
$ HAVE A U-VALUE OF .28.
$ SPACE LOADS LIGHTING IS RECESSED FLUORSCENT NON VENTED AT 1.5 WATTS/SQFT IN
$ THE OFFICES AND 2.2 WATT/SQFT IN THE FLOWER SHOP/ATRIUM.
$ PEOPLE IN OFFICES IS INPUT AT 150SQFT/PERSON.
$ PEOPLE IN ATRIUM ARE 6.
$ INFILTRATION IS SET AT .2 AIRCHANGES/HR WHEN FANS ARE OFF AND AT
$ .1 AIRCHANGE WHEN FANS ARE ON.
$ EQUIPMENT IN OFFICES IS SET AT 1 WATTS/SQFT AND 1.5 W/SQFT IN
$ THE FLOWER SHOP/ATRIUM.
$ CONSTRUCTIONS
ROOF-O =LAYERS MAT=(BR01,IN76,CC03,AL33,AC03) I-F-R=.76 ..
ROOF-A =LAYERS MAT=(BR01,IN76,CC04) I-F-R .76 ..
OFF-ROF =CONSTRUCTION LAYERS ROOF-O ..
ATR-ROF =CONSTRUCTION LAYERS ROOF-A ..
WALL-1 =LAYERS MAT=(CC33,IN35,AL21,GP04,GP04) ..
WL1 =CONSTRUCTION LAYERS=WALL-1 ..
BW1 =CONSTRUCTION U=.05 ..
BW2 =CONSTRUCTION U=.0001 ..
WL2 =CONSTRUCTION U=1.05 $ ATRIUM GLASS PARTITIONS $ ..
WL3 =CONSTRUCTION U=.28 $ INTERIOR PARTITIONS $ ..
$ GLASS DESCRIPTION
GT1 =GLASS-TYPE GLASS-TYPE-CODE 5 PANES 2 ..
GT2 =GLASS-TYPE G-T-C 5 PANES 2 ..
$ This command calls the file containing schedules
$ for offices that is on the sample run input
$ tape. It MUST reside in a directory on your
$ computer system so that this demonstration
$ of a GENERALIZED LIBRARY can function. For users
$ with a large computer system the file name should
$ include the full path name, or as an alternative
$ use the ##fileprefix command.
$ for unix: ##fileprefix /u3/doe2/21e/samples/
$ for vax: ##fileprefix [doe2.21e.samples]
##include officsch.inc
$ FLOWER SHOP SCHEDULES $
OC4 = D-SCH (1,7) (0) (8,11) (.1,.2,.5,.5) (12,15) (.7)
(16,21) (.8,.7,.5,.5,.3,.3) (22,24) (0) ..
OC5 = D-SCH (1,7) (0) (8,11) (.1,.2,.5,.6) (12,17) (.8)
(18,22) (.6,.2,.2,.2,.1) (23,24) (0) ..
OC6 = D-SCH (1,24) (0) ..
OCCUP2 = SCH THRU DEC 31 (WD) OC4 (SAT) OC5 (SUN,HOL) OC6 ..
L4 = D-SCH (1,7) (0) (8,9) (.2,.5) (10,18) (.9)
(19,24) (.6,.6,.5,.2,0,0) ..
L5 = D-SCH (1,7) (0) (8,10) (.1,.3,.6) (11,18) (.9)
(19,24) (.5,.3,.3,.1,0,0) ..
L6 = D-SCH (1,24) (0) ..
LIGHTS2 = SCH THRU DEC 31 (WD) L4 (SAT) L5 (SUN,HOL) L6 ..
IF4 = D-SCH (1,6) (1) (7,21) (0) (22,24) (1) ..
IF5 = D-SCH (1,6) (1) (7,22) (0) (23,24) (1) ..
IF6 = D-SCH (1,24) (1) ..
INFIL = SCH THRU DEC 31 (WD) IF4 (SAT) IF5 (SUN,HOL) IF6 ..
EQ2 = SCH THRU DEC 31 (ALL) (1,24) (1) .. $ REFRIGERATOR COMPRESSOR HEAT
$ REJECTED TO SPACE
SHADE-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.6) ..
COND-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.90) ..
CLOSE-SHADE =SCHEDULE THRU DEC 31 (ALL) (1,24) (40) ..
REOPEN-PROB =SCHEDULE THRU DEC 31 (ALL) (1,24) (.2) ..
$ SET DEFAULTS
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=10 AZIMUTH=180
CONSTRUCTION=WL1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4 Y=4 GLASS-TYPE=GT1
MAX-SOLAR-SCH=CLOSE-SHADE SUN-CTRL-PROB .7
WIN-SHADE-TYPE=MOVABLE-INTERIOR
SHADING-SCHEDULE=SHADE-MULT
CONDUCT-SCHEDULE=COND-MULT
OPEN-SHADE-SCH=REOPEN-PROB ..
$ SPACE DESCRIPTION
OFFICE =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=70
EQUIPMENT-W/SQFT=1 EQUIP-SCHEDULE=EQ1
LIGHTING-W/SQFT=1.5 LIGHTING-SCHEDULE=LT1
INF-METHOD=AIR-CHANGE AIR-CHANGES/HR=.2
LIGHTING-TYPE=SUS-FLUOR
PEOPLE-HG-LAT=200 PEOPLE-HG-SENS=250
PEOPLE-SCHEDULE=OCCUP ..
ATRIUM =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=100
LIGHTING-SCHEDULE=LIGHTS2
LIGHTING-TYPE=INCAND
LIGHTING-W/SQFT=2.2
EQUIP-SCHEDULE=EQ2
EQUIPMENT-W/SQFT=1.5
NUMBER-OF-PEOPLE=6
PEOPLE-HEAT-GAIN= 550
PEOPLE-SCHEDULE = OCCUP2
INF-SCHEDULE=INFIL AIR-CHANGES/HR=.2
INF-METHOD=AIR-CHANGE ..
BZ1 =SPACE S-C=OFFICE NUMBER-OF-PEOPLE=20
AREA=3230 VOLUME=29070 AZ=90 Y=200 ..
E1 =EXTERIOR-WALL WIDTH=200 ..
W1 =WINDOW WIDTH=200 ..
E1S =EXTERIOR-WALL W=17 AZ=90 X=200 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
BZ2 =SPACE S-C=OFFICE AREA=1660 VOLUME=14940
NUMBER-OF-PEOPLE=10 AZ=180 X=100 Y=200 ..
E2 =EXTERIOR-WALL WIDTH=100 ..
W2 =WINDOW WIDTH=100 ..
UNDERGROUND-FLOOR AREA=1660 CONS=BW1 ..
BZ3 =SPACE LIKE BZ1 AZ=-90 X=100 Y=0 ..
E3 =EXTERIOR-WALL LIKE E1 ..
W3 =WINDOW LIKE W1 ..
E3S =EXTERIOR-WALL W=17 AZ=270 Y=17 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
TZ1 =SPACE LIKE BZ1 Z=10 ..
R1 =ROOF H=17 W=200 AZ=180 TILT=0 Z=10
CONS=OFF-ROF ..
EXTERIOR-WALL LIKE E1 ..
WINDOW LIKE W1 ..
EXTERIOR-WALL LIKE E1S ..
TZ2 =SPACE LIKE BZ2 Z=10 ..
ROOF LIKE R1 H=20 W=83 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE BZ3 Z=10 ..
ROOF LIKE R1 H=17 W=180 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
EXTERIOR-WALL LIKE E3S ..
IZ1 =SPACE S-C=OFFICE AREA=3540 VOLUME=70800
NUMBER-OF-PEOPLE=40 AZ=90 X=17 Y=180 ..
IN1 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ1 CONS=WL2 ..
IN2 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ2 CONS=WL2 ..
IN3 =INTERIOR-WALL AREA=800 NEXT-TO EQUIP-RM CONS=WL3 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 Y=18 Z=20 ..
EXTERIOR-WALL H=20 W=18 AZ=90 X=180 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
IZ2 =SPACE LIKE IZ1 AZ=-90 X=83 Y=0 ..
INTERIOR-WALL LIKE IN1 NEXT-TO ATZ1 ..
INTERIOR-WALL LIKE IN2 NEXT-TO ATZ2 ..
INTERIOR-WALL LIKE IN3 ..
EXTERIOR-WALL H=20 W=18 AZ=270 Y=18 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 X=160 Y=18 Z=20 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
ATZ1 =SPACE S-C=ATRIUM AREA=1800 VOLUME=16200
X=35 Y=40 ..
ATROOF-1 =ROOF HEIGHT=66.6 WIDTH=30
AZIMUTH=0 TILT=26 X=30 Y=60 Z=20
CONS=ATR-ROF ..
E4 =EXTERIOR-WALL H=14.5 W=60 AZ=270 Y=60 Z=20 ..
E5 =EXTERIOR-WALL LIKE E4 AZ=90 X=30 Y=0 ..
F1 =UNDERGROUND-FLOOR AREA=1800 CONS=BW2 ..
FRAME-A =EXTERIOR-WALL HEIGHT=29 WIDTH=30 Z=20 ..
WINDOW-A =WINDOW H=28.9 W=29.9 X=.05 Y=.05 GLASS-TYPE=GT2
OVERHANG-A=6 OH-B=0 OH-D=48.5 OH-W=42
OVERHANG-ANGLE=116 LEFT-FIN-A=0 L-F-B=0
L-F-H=30 L-F-D=3 RIGHT-FIN-A=0 R-F-B=0
R-F-H=30 R-F-D=3 ..
EXTERIOR-WALL LIKE FRAME-A HEIGHT=10.7 W=30 Z=9.3 ..
WINDOW LIKE WINDOW-A H=10.6 W=29.9 L-F-H=10.7
R-F-H=10.7 ..
ATZ2 =SPACE LIKE ATZ1 Y=100 ..
ATROOF-2 =ROOF LIKE ATROOF-1 ..
EXTERIOR-WALL LIKE E4 ..
EXTERIOR-WALL LIKE E5 ..
UNDERGROUND-FLOOR LIKE F1 ..
FRAME-B =EXTERIOR-WALL LIKE FRAME-A ..
WINDOW-B =WINDOW LIKE WINDOW-A ..
EQUIP-RM =SPACE ZONE-TYPE=UNCONDITIONED
AREA=1200 VOLUME=17580 X=35 ..
EXTERIOR-WALL HEIGHT=20 WIDTH=30 ..
ROOF H=41.2 W=30 CONS=OFF-ROF
TILT=15 Z=9.3 X=30 Y=40 AZIMUTH=0 ..
INTERIOR-WALL AREA=279 CONS=WL3 NEXT-TO ATZ1 ..
UNDERGROUND-FLOOR AREA=1200 CONS=BW1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY (SS-D,SS-A,SS-J) ..
SUBR-FUNCTIONS DKTEMP-3=*dktempF* ..
$ HVAC SYSTEMS DESCRIPTION
$ DESIGN TEMPS ATRIUM COOLING 76F-SUMMER, 72F-WINTER HEATING SETBACK 65F
$ OFFICE COOLING 76F HEATING 72F
$ SYSTEM TYPE THE OFFICE IS SERVED BY A VAVS SYSTEM.
$ THE ATRIUM/FLOWER SHOP IS SERVED BY A REHEAT SYSTEM CONVERTED
$ TO A CONSTANT VOLUME-VARIABLE TEMPERATURE SYSTEM. THE FUNCTION
$ FEATURE IS USED TO SIMULATE THE CONTROL OF THIS UNIT BY USING A
$ RETURN AIR STAT RATHER THAN HOLDING THE SUPPLY TEMPERATURE
$ CONSTANT. THIS IS A VERY COMMON MODELING REQUIREMENT AS MANY
$ REHEAT SYSTEMS HAD BOILERS TURNED OFF IN THE SUMMER AND OVER-
$ COOLED WITHOUT SOME WAY TO MODULATE THE SUPPLY AIR TEMPERATURE.
$ BOTH SYSTEMS HAVE DRY BULB ECONOMIZERS WITH A 68F LIMIT ON THE
$ VAV SYSTEM AND ON THE REHEAT SYSTEM.
$ AIR HANDLING UNIT SCHEDULES
DAYS = WEEK-SCHEDULE (MON,SAT) (1,7)(0)(8,9)(-999)(10,21)(1)(22,24)(0)
(SUN,HOL) (1,24)(0) ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS ..
$ HEATING THERMOSTAT SCHEDULE
THEAT1 = SCHEDULE THRU DEC 31 (MON,SAT) (1,7)(65)(8,21)(72)(22,24)(65)
(SUN,HOL) (1,24)(65) ..
$ COOLING THERMOSTAT SCHEDULE
TCOOL1 = SCHEDULE THRU DEC 31 (MON,SAT) (1,7)(90)(8,21)(76)(22,24)(90)
(SUN,HOL) (1,24)(90) ..
MIN-OA = SCHEDULE THRU DEC 31 (ALL) (1,9)(0) (10,21)(-999) (22,24)(0) ..
HEAT-OFF-SUM = SCHEDULE THRU MAY 15 (ALL) (1,24) (1)
THRU OCT 15 (ALL) (1,24) (0)
THRU DEC 31 (ALL) (1,24) (1) ..
$ ZONE DESCRIPTION
ENV-ATR = ZONE-CONTROL D-H-T 72 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL1
T-TYPE PROPORTIONAL ..
ENV-OFF = ZONE-CONTROL D-H-T 74 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL1
T-TYPE REVERSE-ACTION ..
ATZ1 = ZONE Z-C ENV-ATR OUTSIDE-AIR-CFM 665 ..
ATZ2 = ZONE LIKE ATZ1 ..
EQUIP-RM = ZONE ZONE-TYPE=UNCONDITIONED ..
BZ1 = ZONE Z-C ENV-OFF OA-CFM/PER=15 ..
BZ2 = ZONE LIKE BZ1 ..
BZ3 = ZONE LIKE BZ1 ..
TZ1 = ZONE LIKE BZ1 ..
TZ2 = ZONE LIKE BZ1 ..
TZ3 = ZONE LIKE BZ1 ..
IZ1 = ZONE LIKE BZ1 ..
IZ2 = ZONE LIKE BZ1 ..
FS-SYS = SYSTEM SYSTEM-TYPE=RHFS MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=3 SUPPLY-EFF=.45 ECONO-LIMIT-T 68
FAN-SCHEDULE=AHU-SCHED REHEAT-DELTA-T 50
HEATING-SCHEDULE=HEAT-OFF-SUM
NIGHT-CYCLE-CTRL=CYCLE-ON-FIRST
ZONE-NAMES=(ATZ1,ATZ2,EQUIP-RM)
FUNCTION=(*sfn0*,*sfn1*) ..
OFF-SYS = SYSTEM SYSTEM-TYPE=VAVS MAX-S-T=120 MIN-S-T=60
SUPPLY-STATIC=5 SUPPLY-EFF=.55 ECONO-LIMIT-T=68
FAN-SCHEDULE=AHU-SCHED MIN-CFM-RATIO=.3
FAN-CONTROL=SPEED HEAT-SET-T=100
RETURN-AIR-PATH=DUCT OA-CONTROL=TEMP
NIGHT-CYCLE-CTRL=CYCLE-ON-ANY
MIN-AIR-SCH=MIN-OA REHEAT-DELTA-T=55
ZONE-NAMES=(BZ1,BZ2,BZ3,TZ1,TZ2,TZ3,IZ1,IZ2) ..
PLANT1 = PLANT-ASSIGNMENT SYSTEM-NAMES = (FS-SYS,OFF-SYS)
DHW-SIZE = 0
DHW-GAL/MIN = 2.22
DHW-SCH = DOMHW ..
D1 = D-SCH (1,7) (0) (8,21) (.1,.2,.3,.4,.55,.6,.6,.45,.4,.45,.45,.4,.3,.3)
(22,24) (0) ..
D2 = D-SCH (1,7) (0) (8,22) (.15,.2,.25,.4,.5,.55,.55,.45,.45,.45,.45,.4,.35,
.25,.2) (23,24) (0) ..
D3 = D-SCH (1,9) (0) (10,19) (.1,.25,.3,.35,.35,.3,.3,.35,.3,.2)
(20,24) (0) ..
DOMHW = SCH THRU DEC 31 (WD) D1 (SAT) D2 (SUN,HOL) D3 ..
END ..
$ THE FOLLOWING IS THE FUNCTION INPUT TO CONTROL THE SUPPLY AIR TEMPERATURE OF
$ THE REHEAT UNIT WITH A RETURN AIR THERMOSTAT.
FUNCTION NAME=dktempF ..
ASSIGN IHR=IHR IDAY=IDAY IMO=IMO INILZE=INILZE ..
ASSIGN TR=TR $ return air temp $
TC=TC $ suppy temp $
TH=TH $ hot-deck temp $ ..
ASSIGN TCTR=TABLE (70,70) (80,50) .. $ pwl function of tc vs tr $
ASSIGN TRLAST = F-SYS-VAR1 ..
CALCULATE ..
IF ( (IDAY .EQ. 7) .AND. (IMO .EQ. 7) )
1 PRINT 1, IMO, IDAY, IHR, TC, TH, TRLAST
1 FORMAT( ' dktempF-- IMO, IDAY, IHR=',3f3.0,' TC='f7.2,' TH='f7.2
1 ' TRLAST='f7.2 )
IF( TRLAST .EQ. 0. ) RETURN
TC = PWL( TCTR, TRLAST )
IF ( (IDAY .EQ. 7) .AND. (IMO .EQ. 7) )
1 PRINT 2, TC
2 FORMAT( ' new TC='f7.2 )
END
END-FUNCTION ..
FUNCTION NAME=sfn0 LEVEL=BUILDING ..
ASSIGN IHR=IHR IDAY=IDAY IMO=IMO INILZE=INILZE ..
ASSIGN TR=TR $ return air temp $
TC=TC $ suppy temp $
TH=TH $ hot-deck temp $ ..
CALCULATE ..
IF( INILZE .LT. 4 ) RETURN
IF( (IDAY .NE. 7) .OR. (IMO .NE. 7) ) RETURN
PRINT 9
9 FORMAT(1X)
PRINT 1, IMO, IDAY, IHR, TC, TH, TR
1 FORMAT( ' sfn0 -- IMO, IDAY, IHR=',3f3.0,' TC=',f7.2,
1 ' TH=',f7.2,' TR=',f7.2 )
END
END-FUNCTION ..
FUNCTION NAME=sfn1 LEVEL=BUILDING ..
ASSIGN IHR=IHR IDAY=IDAY IMO=IMO INILZE=INILZE ..
ASSIGN TR=TR $ return air temp $
TC=TC $ suppy temp $
TH=TH $ hot-deck temp $ ..
ASSIGN TRLAST = F-SYS-VAR1 ..
CALCULATE ..
C--- store TR for use by 'dktempF'
TRLAST = TR
IF( INILZE .LT. 4 ) RETURN
IF ( (IDAY .NE. 7) .OR. (IMO .NE. 7) ) RETURN
PRINT 1, IMO, IDAY, IHR, TC, TH, TR
1 FORMAT( ' sfn1 -- IMO, IDAY, IHR=',3f3.0,' TC=',f7.2,
1 ' TH=',f7.2,' TR=',f7.2 )
END
END-FUNCTION ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
PLANT-REPORT SUMMARY (PS-A,PS-D,BEPS) ..
PLANT1 = PLANT-ASSIGNMENT ..
$ PLANT DESCRIPTION
$ THIS PLANT IS SERVED BY A DIRECT-FIRED ABSORPTION CHILLER/HWG COMBINATION
$ UNIT WHERE THE CAPACITY OF THE HWG IS SET TO THE CAPACITY OF THE CHILLER,
$ WHICH IS THE GREATER OF THE TWO REQUIREMENTS. OTHERWISE A HWG WOULD HAVE
$ BEEN REQUIRED TO SUPPLEMENT THE CHLR/HTR. A DOMESTIC HOT WATER HEATER IS
$ ALSO REQUIRED.
CHL = PLANT-EQUIPMENT TYPE=ABSORG-CHLR SIZE -999 I-N 1 ..
DHW = PLANT-EQUIPMENT TYPE=DHW-HEATER SIZE -999 I-N 1 ..
CTR = PLANT-EQUIPMENT TYPE=COOLING-TWR SIZE -999 ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
DIAGNOSTIC WARNINGS ..
ECONOMICS-REPORT SUMMARY (ES-D,ES-E) ..
$ ENERGY CHARGE DESCRIPTION
$ THIS RATE STRUCTURE IS A TYPICAL SMALL COMMERCIAL TIME OF DAY TYPE WITH AND
$ INVERTED RATE. IN OTHER WORDS ENERGY COSTS INCREASE AS CONSUMPTION RISES.
$ THERE IS A BASE CHARGE OF 2 CENTS/KWH PLUS A FIXED MONTHLY CHARGE OF 200
$ DOLLARS. ON TOP OF THESE CHARGES FALL THE KWH/KW ENERGY CHARGE FOR EACH
$ SEASON. THERE IS A LIMITATION OF 15000 KWHS FOR THE FIRST BLOCK.
$ NATURAL GAS IS A FLAT RATE OF 60 CENTS PER THERM.
ELEC-COST = UTILITY-RATE RESOURCE = ELECTRICITY
MONTH-CHGS (200)
BLOCK-CHARGES = (WIN-OFF-P,WIN-ON-P,
SUM-OFF-P,SUM-ON-P)
ENERGY-CHG = .02 ..
WIN-OFF-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 1.1
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.025,15000,
1,.035,0) ..
WIN-ON-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 1.2
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.040,15000,
1,.050,0) ..
SUM-OFF-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 2.1
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.025,15000,
1,.035,0) ..
SUM-ON-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 2.2
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (150,.045,15000,
1,.055,0) ..
TOU-CHGS = SCHEDULE THRU MAY 15 (ALL)(1,12)(1.1)
(13,17)(1.2)
(18,24)(1.1)
THRU OCT 20 (ALL)(1,12)(2.1)
(13,18)(2.2)
(19,24)(2.1)
THRU DEC 31 (ALL)(1,12)(1.1)
(13,17)(1.2)
(18,24)(1.1) ..
GAS-COST = UTILITY-RATE RESOURCE = NATURAL-GAS
ENERGY-CHG = .60 ..
END ..
COMPUTE ECONOMICS ..
INPUT LOADS ..
TITLE LINE-1 * OFFICE BUILDING & DELI/RESTAURANT*
LINE-2 * ELECTROCHROMIC GLAZING IN ATRIUM *
LINE-3 * VAV SYSTEM IN OFFICE & PSZ IN ATRIUM *
LINE-4 * GAS ENGINE DRIVEN CHILLER & HEAT RECY*
LINE-5 * SAMP3.INP RUN 3 * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD JAN 1 1988 THRU DEC 31 1988 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
LOADS-REPORT SUMMARY=(LS-D) ..
$ BUILDING DESCRIPTION
$ THE MEDICAL OFFICE BUILDING ABOVE HAS BEEN REMODELED WITH
$ DIFFERENT USAGES TO DEMONSTRATE NEW FEATURES OF DOE-2.1D and E.
$ STRUCTURE REINFORCED CONCRETE CONSTRUCTION WITH 4IN CONCRETE FLOORS AND ROOF
$ 10FT FLOOR TO FLOOR HEIGHT, TWO STORIES HIGH. RETURN AIR PLENUMS
$ ARE NOT DEFINED.
$ WALLS USING CODE WORDS FROM THE DOE-2 LIBRARY (REFERENCE MANUAL PART 2)
$ AND STARTING WITH THE OUTSIDE SURFACE AND MOVING INWARD:
$ 2IN PRECAST CONCRETE PANEL (CC03); 2IN POLYSTRENE INSULATION
$ R-8 (IN35); 3IN AIRSPACE (AL21); 5/8IN GYPSUM BOARD (GP04);
$ 3/4IN FINISH PLASTER.
$ ATRIUM ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 6IN CONCRETE (CC04); INSIDE FILM RESISTANCE .76
$ OFFICE ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 2 FT AIR SPACE (AL33); 3/4IN LAY-IN ACOUSTIC TILE (AC03);
$ INSIDE-FILM-RESISTANCE .76.
$ FLOORS FIRST FL IS SLAB-ON-GRADE EFFECTIVE U-VALUE OF ENTIRE AREA .05.
$ WINDOWS OFFICE AREA 4FT HIGH AND FULL WIDTH OF EACH WALL, EXCEPT SOUTH
$ WALL WHERE THERE ARE NO WINDOWS. EXCEPT FOR ATRIUM, GLASS IS
$ DOUBLE-PANE TINTED WITH A SOLAR TRANSMITTANCE OF 0.53.
$
$ ATRIUM GLAZING IS ELECTROCHROMIC, SWITCHING FROM CLEAR TO
$ COLORED (TO REDUCE SOLAR GAIN) WHEN ATRIUM HAS A COOLING LOAD
$ (AS DETERMINED BY THE LOADS PROGRAM) THE PREVIOUS HOUR.
$ THERE ARE TWO MAIN SECTIONS OF GLASS 29' WIDE BY
$ 30' HIGH WITH NO OVERHANGS OR SIDE FINS.
$ INTERIORS CEILINGS ARE SIMULATED AS PART OF THE ROOF STRUCTURE ON THE TOP
$ FLOOR. PARTITIONS SIMULATE A GLASS WALL BETWEEN ATRIUM AND
$ OFFICE SPACES, BUT WALLS BETWEEN INTERIOR AND EXTERIOR OFFICES
$ ARE NOT DEFINED. WALLS BETWEEN THE EQUIPMENT ROOM AND OFFICES
$ HAVE A U-VALUE OF .28.
$ SPACE LOADS LIGHTING IS RECESSED FLUORSCENT NON VENTED AT 1.5 WATTS/SQFT
$ IN THE OFFICES AND 2.2 WATT/SQFT IN THE ATRIUM.
$ PEOPLE IN OFFICES IS INPUT AT 150SQFT/PERSON.
$ PEOPLE IN ATRIUM ARE ZERO.
$ INFILTRATION IS SET AT .2 AIRCHANGES/HR WHEN FANS ARE OFF AND AT
$ .1 AIRCHANGE WHEN FANS ARE ON.
$ EQUIPMENT IN OFFICES IS SET AT 1 WATTS/SQFT AND 1.5 WATTS/SQFT
$ IN THE ATRIUM.
$ CONSTRUCTIONS
ROOF-O =LAYERS MAT=(BR01,IN76,CC03,AL33,AC03) I-F-R=.76 ..
ROOF-A =LAYERS MAT=(BR01,IN76,CC04) I-F-R .76 ..
OFF-ROF =CONSTRUCTION LAYERS ROOF-O ..
ATR-ROF =CONSTRUCTION LAYERS ROOF-A ..
WALL-1 =LAYERS MAT=(CC33,IN35,AL21,GP04,GP04) ..
WL1 =CONSTRUCTION LAYERS=WALL-1 ..
BW1 =CONSTRUCTION U=.05 ..
BW2 =CONSTRUCTION U=.0001 ..
WL2 =CONSTRUCTION U=1.05 $ ATRIUM GLASS PARTITIONS $ ..
WL3 =CONSTRUCTION U=.28 $ INTERIOR PARTITIONS $ ..
$ GLASS DESCRIPTION
GT1 =GLASS-TYPE GLASS-TYPE-CODE=5 PANES=2 ..
$ GLASS TYPES FOR SWITCHABLE GLAZING IN ATRIUM WINDOWS
ELECTRO-CLEAR =GLASS-TYPE GLASS-TYPE-CODE=2800 .. $ ELECTROCHROMIC ABSORBIN,
$ BLEACHED STATE
$ SHADING COEF = .85
ELECTRO-COLOR =GLASS-TYPE GLASS-TYPE-CODE=2801 .. $ ELECTROCHROMIC ABSORBING,
$ COLORED STATE
$ SHADING COEF = .21
$ The following command calls the file containing schedules
$ for offices that is on the sample run input
$ tape. It MUST reside in a directory on your
$ computer system so that this demonstration
$ of a GENERALIZED LIBRARY can function. For users
$ with a large computer system the file name should
$ include the full path name, or as an alternative
$ use the ##fileprefix command.
$ for unix: ##fileprefix /u3/doe2/21e/samples/
$ for vax: ##fileprefix [doe2.21e.samples]
##include officsch.inc
$ DELI/RESTAURANT SCHEDULES $
OC4 = D-SCH (1,7) (0) (8,11) (.1,.2,.5,.5) (12,15) (.7)
(16,21) (.8,.7,.5,.5,.3,.3) (22,24) (0) ..
OC5 = D-SCH (1,7) (0) (8,11) (.1,.2,.5,.6) (12,17) (.8)
(18,22) (.6,.2,.2,.2,.1) (23,24) (0) ..
OC6 = D-SCH (1,24) (0) ..
OCCUP2 = SCH THRU DEC 31 (WD) OC4 (SAT) OC5 (SUN,HOL) OC6 ..
L4 = D-SCH (1,7) (0) (8,9) (.2,.5) (10,18) (.9)
(19,24) (.6,.6,.5,.2,0,0) ..
L5 = D-SCH (1,7) (0) (8,10) (.1,.3,.6) (11,18) (.9)
(19,24) (.5,.3,.3,.1,0,0) ..
L6 = D-SCH (1,24) (0) ..
LIGHTS2 = SCH THRU DEC 31 (WD) L4 (SAT) L5 (SUN,HOL) L6 ..
IF4 = D-SCH (1,6) (1) (7,21) (0) (22,24) (1) ..
IF5 = D-SCH (1,6) (1) (7,22) (0) (23,24) (1) ..
IF6 = D-SCH (1,24) (1) ..
INFIL = SCH THRU DEC 31 (WD) IF4 (SAT) IF5 (SUN,HOL) IF6 ..
EQ2 = SCH THRU DEC 31 (ALL) (1,24) (1) .. $ REFRIGERATOR COMPRESSOR HEAT
$ REJECTED TO SPACE
$ SET DEFAULTS
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=10 AZIMUTH=180
CONSTRUCTION=WL1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4 Y=4 GLASS-TYPE=GT1 ..
$ SPACE DESCRIPTION
OFFICE =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=70
EQUIPMENT-W/SQFT=1 EQUIP-SCHEDULE=EQ1
LIGHTING-W/SQFT=1.5 LIGHTING-SCHEDULE=LT1
INF-METHOD=AIR-CHANGE AIR-CHANGES/HR=.2
LIGHTING-TYPE=SUS-FLUOR
PEOPLE-HG-LAT=200 PEOPLE-HG-SENS=250
PEOPLE-SCHEDULE=OCCUP ..
ATRIUM =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=100
LIGHTING-SCHEDULE=LIGHTS2
LIGHTING-TYPE=INCAND
LIGHTING-W/SQFT=2.2
EQUIP-SCHEDULE=EQ2
EQUIPMENT-W/SQFT=1.5
NUMBER-OF-PEOPLE=6
PEOPLE-HEAT-GAIN= 550
PEOPLE-SCHEDULE = OCCUP2
INF-SCHEDULE=INFIL AIR-CHANGES/HR=.2
INF-METHOD=AIR-CHANGE ..
BZ1 =SPACE S-C=OFFICE NUMBER-OF-PEOPLE=20
AREA=3230 VOLUME=29070 AZ=90 Y=200 ..
E1 =EXTERIOR-WALL WIDTH=200 ..
W1 =WINDOW WIDTH=200 ..
E1S =EXTERIOR-WALL W=17 AZ=90 X=200 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
BZ2 =SPACE S-C=OFFICE AREA=1660 VOLUME=14940
NUMBER-OF-PEOPLE=10 AZ=180 X=100 Y=200 ..
E2 =EXTERIOR-WALL WIDTH=100 ..
W2 =WINDOW WIDTH=100 ..
UNDERGROUND-FLOOR AREA=1660 CONS=BW1 ..
BZ3 =SPACE LIKE BZ1 AZ=-90 X=100 Y=0 ..
E3 =EXTERIOR-WALL LIKE E1 ..
W3 =WINDOW LIKE W1 ..
E3S =EXTERIOR-WALL W=17 AZ=270 Y=17 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
TZ1 =SPACE LIKE BZ1 Z=10 ..
R1 =ROOF H=17 W=200 AZ=180 TILT=0 Z=10
CONS=OFF-ROF ..
EXTERIOR-WALL LIKE E1 ..
WINDOW LIKE W1 ..
EXTERIOR-WALL LIKE E1S ..
TZ2 =SPACE LIKE BZ2 Z=10 ..
ROOF LIKE R1 H=20 W=83 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE BZ3 Z=10 ..
ROOF LIKE R1 H=17 W=180 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
EXTERIOR-WALL LIKE E3S ..
IZ1 =SPACE S-C=OFFICE AREA=3540 VOLUME=70800
NUMBER-OF-PEOPLE=40 AZ=90 X=17 Y=180 ..
IN1 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ1 CONS=WL2 ..
IN2 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ2 CONS=WL2 ..
IN3 =INTERIOR-WALL AREA=800 NEXT-TO EQUIP-RM CONS=WL3 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 Y=18 Z=20 ..
EXTERIOR-WALL H=20 W=18 AZ=90 X=180 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
IZ2 =SPACE LIKE IZ1 AZ=-90 X=83 Y=0 ..
INTERIOR-WALL LIKE IN1 NEXT-TO ATZ1 ..
INTERIOR-WALL LIKE IN2 NEXT-TO ATZ2 ..
INTERIOR-WALL LIKE IN3 ..
EXTERIOR-WALL H=20 W=18 AZ=270 Y=18 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 X=160 Y=18 Z=20 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
ATZ1 =SPACE S-C=ATRIUM AREA=1800 VOLUME=16200
X=35 Y=40 ..
ATROOF-1 =ROOF HEIGHT=66.6 WIDTH=30
AZIMUTH=0 TILT=26 X=30 Y=60 Z=20
CONS=ATR-ROF ..
E4 =EXTERIOR-WALL H=14.5 W=60 AZ=270 Y=60 Z=20 ..
E5 =EXTERIOR-WALL LIKE E4 AZ=90 X=30 Y=0 ..
F1 =UNDERGROUND-FLOOR AREA=1800 CONS=BW2 ..
FRAME-A =EXTERIOR-WALL HEIGHT=29 WIDTH=30 Z=20 ..
WINDOW-A =WINDOW H=28.9 W=29.9 X=.05 Y=.05
GLASS-TYPE = ELECTRO-CLEAR
GLASS-TYPE-SW = ELECTRO-COLOR
SWITCH-CONTROL = SPACE-LOAD
SWITCH-SET-LO = 0
SWITCH-SET-HI = 0 ..
EXTERIOR-WALL LIKE FRAME-A HEIGHT=10.7 W=30 Z=9.3 ..
WINDOW LIKE WINDOW-A H=10.6 W=29.9 ..
ATZ2 =SPACE LIKE ATZ1 Y=100 ..
ATROOF-2 =ROOF LIKE ATROOF-1 ..
EXTERIOR-WALL LIKE E4 ..
EXTERIOR-WALL LIKE E5 ..
UNDERGROUND-FLOOR LIKE F1 ..
FRAME-B =EXTERIOR-WALL LIKE FRAME-A ..
WINDOW-B =WINDOW LIKE WINDOW-A ..
EQUIP-RM =SPACE ZONE-TYPE=UNCONDITIONED
AREA=1200 VOLUME=17580 X=35 ..
EXTERIOR-WALL HEIGHT=20 WIDTH=30 ..
ROOF H=41.2 W=30 CONS=OFF-ROF
TILT=15 Z=9.3 X=30 Y=40 AZIMUTH=0 ..
INTERIOR-WALL AREA=279 CONS=WL3 NEXT-TO ATZ1 ..
UNDERGROUND-FLOOR AREA=1200 CONS=BW1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY (SS-D,SS-A,SS-J) ..
$ HVAC SYSTEMS DESCRIPTION
$ DESIGN TEMPS ATRIUM COOLING 76F-SUMMER, 72F-WINTER HEATING SETBACK 65F
$ OFFICE COOLING 76F HEATING 72F
$ SYSTEM TYPE THE OFFICE IS SERVED BY A VAVS SYSTEM WITH THE BASEBOARD RESET
$ BY THE OUTSIDE AIR TEMPERATURE.
$ THE RESTAURANT/DELI IS SERVED BY 2 PKG VARIABLE TEMPERATURE -
$ CONSTANT VOLUME SYSTEMS (PSZ). THE UNIT SERVING THE DELI WHICH
$ HAS OPEN CASEWORK FOR DISPLAY OF FOOD AND BEVERAGES RECOVERS
$ REJECTED HEAT. THIS SIMULATION CAN ALSO BE USED FOR GROCERY
$ STORES.
$ BOTH SYSTEMS HAVE DRY BULB ECONOMIZERS WITH A 68F LIMIT ON THE
$ VAV SYSTEM AND A 25 BTUH/#DRY AIR ENTHALPY LIMIT AND A 74F
$ DRYBULB LIMIT ON THE PKG DX UNITS REPRESENTATIVE OF PKG'D
$ CONTROLLERS. THE UNITS ARE ALSO FITTED WITH AN ECONO LOCKOUT
$ WHICH PROTECTS THE COMPRESSOR FROM BURNOUT ON LOW EVAPORATOR
$ LOADING.
$ AIR HANDLING UNIT SCHEDULES
DAYS = WEEK-SCHEDULE (MON,SAT) (1,7)(0)(8,21)(1)(22,24)(0)
(SUN,HOL) (1,24)(0) ..
AHU-SCHED = SCHEDULE THRU DEC 31 DAYS ..
AHU-SCHED2 = SCHEDULE THRU DEC 31 (ALL) (1,24)(1) ..
$ HEATING THERMOSTAT SCHEDULE
THEAT1 = SCHEDULE THRU DEC 31 (MON,SAT) (1,7)(65)(8,21)(72)(22,24)(65)
(SUN,HOL) (1,24)(65) ..
$ COOLING THERMOSTAT SCHEDULES
TCOOL1 = SCHEDULE THRU DEC 31 (MON,SAT) (1,7)(90)(8,21)(76)(22,24)(90)
(SUN,HOL) (1,24)(90) ..
TCOOL2 = SCHEDULE THRU DEC 31 (ALL) (1,24)(76) ..
$ BASEBOARD RESET SCHEDULE
R1 = DAY-RESET-SCH SUPPLY-HI = 1 SUPPLY-LO = 0
OUTSIDE-LO = 0 OUTSIDE-HI = 50 ..
BASD-RESET = RESET-SCHEDULE THRU DEC 31 (ALL) R1 ..
$ REFRIGERATED CASEWORK SCHEDULES
FOOD-S-S = SCHEDULE THRU DEC 31 (MON,SAT) (1,9)(.4) (10,21)(1) (22,24)(.4)
(SUN,HOL) (1,24)(.4) ..
FOOD-L-S = SCHEDULE THRU DEC 31 (MON,SAT) (1,9)(.7) (10,21)(1) (22,24)(.7)
(SUN,HOL) (1,24)(.7) ..
FOOD-AUX-S = SCHEDULE THRU DEC 31 (MON,SAT) (1,9)(.2) (10,21)(1) (22,24)(.2)
(SUN,HOL) (1,24)(.2) ..
MIN-OA = SCHEDULE THRU DEC 31 (ALL) (1,9)(0) (10,21)(-999) (22,24)(0) ..
$ ZONE DESCRIPTION
ENV-ATR = ZONE-CONTROL D-H-T 70 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL2
T-TYPE PROPORTIONAL ..
ENV-OFF = ZONE-CONTROL D-H-T 74 D-C-T 74 H-T-SCH THEAT1 C-T-SCH TCOOL1
T-TYPE REVERSE-ACTION ..
ATZ1 = ZONE Z-C ENV-ATR OUTSIDE-AIR-CFM 665
REFG-ZONE-LOAD =(-10000,-5000,-6000)
REFG-ZONE-SHR = (.9,.8,.9)
REFG-DISCHARGE-T =(-10,23,30)
REFG-EVAP-T = (-25,20,25)
REFG-SENS-SCH =(FOOD-S-S,FOOD-S-S,FOOD-S-S)
REFG-LAT-SCH = (FOOD-L-S,FOOD-L-S,FOOD-L-S)
REFG-AUX-SCH = (FOOD-AUX-S,FOOD-AUX-S,FOOD-AUX-S)
REFG-DEF-MECH = (RESISTANCE,FREON,FREON)
REFG-DEF-EFF = (.95,.80,.85)
REFG-DEF-CTRL= (THERMOSTATIC,TIMER,TIMER) ..
ATZ2 = ZONE Z-C ENV-ATR OUTSIDE-AIR-CFM 665 ..
EQUIP-RM = ZONE ZONE-TYPE=UNCONDITIONED ..
BZ1 = ZONE Z-C ENV-OFF OA-CFM/PER=15 B-R=-90000 ..
BZ2 = ZONE LIKE BZ1 B-R=-37000 ..
BZ3 = ZONE LIKE BZ1 B-R=-100000 ..
TZ1 = ZONE LIKE BZ1 B-R=-94000 ..
TZ2 = ZONE LIKE BZ1 B-R=-40000 ..
TZ3 = ZONE LIKE BZ1 B-R=-104000 ..
IZ1 = ZONE LIKE BZ1 B-R=-54000 ..
IZ2 = ZONE LIKE BZ1 B-R=-54000 ..
FS-SYS1 = SYSTEM SYSTEM-TYPE=PSZ MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=3 SUPPLY-EFF=.45 DRYBULB-LIMIT=74
ENTHALPY-LIMIT=25 ECONO-LOCKOUT=YES
HEAT-SOURCE=HOT-WATER
REFG-SIZING-RAT =1.3
REFG-COMP-GROUP (SEPARATE,COMMON,COMMON)
REFG-MAX-HTREC = 30000
REFG-HTREC-UNITS = (NO,YES)
ZONE-NAMES = (ATZ1) ..
FS-SYS2 = SYSTEM SYSTEM-TYPE=PSZ MAX-S-T=100 MIN-S-T=55
SUPPLY-STATIC=3 SUPPLY-EFF=.45
FAN-SCHEDULE=AHU-SCHED HEAT-SOURCE=HOT-WATER
NIGHT-CYCLE-CTRL=CYCLE-ON-FIRST
ZONE-NAMES=(ATZ2,EQUIP-RM) ..
OFF-SYS = SYSTEM SYSTEM-TYPE=VAVS MAX-S-T=120 MIN-S-T=60
SUPPLY-STATIC=5 SUPPLY-EFF=.55 ECONO-LIMIT-T=68
FAN-SCHEDULE=AHU-SCHED MIN-CFM-RATIO=.3
FAN-CONTROL=SPEED HEAT-SET-T=100
RETURN-AIR-PATH=DUCT OA-CONTROL=TEMP
N-C-C=CYCLE-ON-ANY REHEAT-DELTA-T=55
MIN-AIR-SCH=MIN-OA BASEBOARD-SCH=BASD-RESET
ZONE-NAMES=(BZ1,BZ2,BZ3,TZ1,TZ2,TZ3,IZ1,IZ2) ..
PLANT1 = PLANT-ASSIGNMENT SYSTEM-NAMES = (FS-SYS1,FS-SYS2,OFF-SYS)
DHW-SIZE = 0
DHW-GAL/MIN = 4.44
DHW-SCH = DOMHW ..
D1 = D-SCH (1,7) (0) (8,21) (.1,.2,.3,.4,.55,.6,.6,.45,.4,.45,.45,.4,.3,.3)
(22,24) (0) ..
D2 = D-SCH (1,7) (0) (8,22) (.15,.2,.25,.4,.5,.55,.55,.45,.45,.45,.45,.4,.35,
.25,.2) (23,24) (0) ..
D3 = D-SCH (1,9) (0) (10,19) (.1,.25,.3,.35,.35,.3,.3,.35,.3,.2)
(20,24) (0) ..
DOMHW = SCH THRU DEC 31 (WD) D1 (SAT) D2 (SUN,HOL) D3 ..
END ..
COMPUTE SYSTEMS ..
INPUT PLANT ..
PLANT1 = PLANT-ASSIGNMENT ..
PLANT-REPORT SUMMARY (PS-A,PS-D,BEPS) ..
$ PLANT DESCRIPTION
$ THIS PLANT IS SERVED BY A SINGLE GAS ENGINE DRIVEN PACKAGED CHILLER WITH
$ HEAT RECOVERY FROM THE ENGINE THAT HEATS DOMESTIC HOT WATER (PROCESS) AND
$ THE BUILDING. A HOT WATER GENERATOR SERVES TO HEAT THE BUILDING WHENEVER
$ THE CHILLER IS NOT IN USE. THE DOMESTIC HOT WATER IS ALSO HEATED BY THE
$ HWG WHENEVER THE CHILLER IN NOT IN USE.
HWG = PLANT-EQUIPMENT TYPE=HW-BOILER SIZE -999 I-N 1 ..
CHLR = PLANT-EQUIPMENT TYPE=ENG-CHLR SIZE -999 I-N 1 ..
HEAT-RECOVERY SUPPLY-1 (ENG-CHLR)
DEMAND-1 (SPACE-HEAT,PROCESS-HEAT) ..
PLANT-PARAMETERS ENG-CH-COP=1.1 ..
END ..
COMPUTE PLANT ..
INPUT ECONOMICS ..
DIAGNOSTIC WARNINGS ..
ECONOMICS-REPORT SUMMARY (ES-D,ES-E) ..
$ ENERGY CHARGE DESCRIPTION
$ THIS RATE STRUCTURE IS A TYPICAL SMALL COMMERCIAL TIME OF DAY TYPE WITH AND
$ INVERTED RATE. IN OTHER WORDS ENERGY COSTS INCREASE AS CONSUMPTION RISES.
$ THERE IS A BASE CHARGE OF 2 CENTS/KWH PLUS A FIXED MONTHLY CHARGE OF 200
$ DOLLARS. ON TOP OF THESE CHARGES FALL THE KWH/KW ENERGY CHARGE FOR EACH
$ SEASON. THERE IS A LIMITATION OF 15000 KWHS FOR THE FIRST BLOCK.
$ NATURAL GAS IS A FLAT RATE OF 60 CENTS PER THERM.
ELEC-COST = UTILITY-RATE RESOURCE = ELECTRICITY
MONTH-CHGS (200)
BLOCK-CHARGES = (WIN-OFF-P,WIN-ON-P,
SUM-OFF-P,SUM-ON-P)
ENERGY-CHG = .02 ..
WIN-OFF-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 1.1
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.025,15000,
1,.035,0) ..
WIN-ON-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 1.2
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.040,15000,
1,.050,0) ..
SUM-OFF-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 2.1
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (200,.025,15000,
1,.035,0) ..
SUM-ON-P = BLOCK-CHARGE BLOCK-SCH = TOU-CHGS
SCH-FLAG = 2.2
BLOCK1-TYPE = KWH/KW
BLOCK1-DATA = (150,.045,15000,
1,.055,0) ..
TOU-CHGS = SCHEDULE THRU MAY 15 (ALL)(1,12)(1.1)
(13,17)(1.2)
(18,24)(1.1)
THRU OCT 20 (ALL)(1,12)(2.1)
(13,18)(2.2)
(19,24)(2.1)
THRU DEC 31 (ALL)(1,12)(1.1)
(13,17)(1.2)
(18,24)(1.1) ..
GAS-COST = UTILITY-RATE RESOURCE = NATURAL-GAS
ENERGY-CHG = .60 ..
END ..
COMPUTE ECONOMICS ..
INPUT LOADS ..
TITLE LINE-1 * OFFICE BUILDING & OPEN ATRIA *
LINE-2 * VAV SYSTEM IN OFFICE & PSZ IN ATRIA *
LINE-3 * ICE THERMAL ENERGY STORAGE FOR OFFICE *
LINE-4 * STORAGE PRIORITY *
LINE-5 * SAMP3.INP RUN 4 * ..
ABORT ERRORS ..
DIAGNOSTIC WARNINGS ..
RUN-PERIOD JUL 4 1986 THRU JUL 11 1986 $ JUL 4TH
$ FALLS ON A FRIDAY PROVIDING A 3DAY
$ HOLIDAY WEEKEND
JAN 1 1986 THRU JAN 5 1986
JAN 1 1986 THRU DEC 31 1986 ..
BUILDING-LOCATION LATITUDE=42 LONGITUDE=88
TIME-ZONE=6 ALTITUDE=610 ..
LOADS-REPORT SUMMARY=(LS-D) ..
$ BUILDING DESCRIPTION
$ STRUCTURE REINFORCED CONCRETE CONSTRUCTION WITH 4IN CONCRETE FLOORS AND ROOF
$ 10FT FLOOR TO FLOOR HEIGHT, TWO STORIES HIGH. RETURN AIR PLENUMS
$ ARE NOT DEFINED.
$ WALLS USING CODE WORDS FROM THE DOE-2 LIBRARY (REFERENCE MANUAL PART 2)
$ AND STARTING WITH THE OUTSIDE SURFACE AND MOVING INWARD:
$ 2IN PRECAST CONCRETE PANEL (CC03); 2IN POLYSTRENE INSULATION
$ R-8 (IN35); 3IN AIRSPACE (AL21); 5/8IN GYPSUM BOARD (GP04);
$ 3/4IN FINISH PLASTER.
$ ATRIUM ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 6IN CONCRETE (CC04); INSIDE FILM RESISTANCE .76
$ OFFICE ROOF BUILT-UP ROOFING (BR01); 3IN ROOF INSULATION R-8 (IN76);
$ 2 FT AIR SPACE (AL33); 3/4IN LAY-IN ACCOUSTIC TILE (AC03);
$ INSIDE-FILM-RESISTANCE .76.
$ FLOORS FIRST FL IS SLAB-ON-GRADE EFFECTIVE U-VALUE OF ENTIRE AREA .05.
$ WINDOWS OFFICE AREA 4FT HIGH AND FULL WIDTH OF EACH WALL, EXCEPT SOUTH
$ WALL WHERE THERE ARE NO WINDOWS. GLASS IS DOUBLE PANE TINTED
$ WITH A SOLAR TRANSMITTANCE OF .53. WINDOWS HAVE INSIDE DRAPES
$ THAT HAVE A PROBABILITY OF.7 OF BEING PULLED WHEN TRANSMITTED
$ DIRECT RADIATION IS GREATER THAN 40 BTUH. DRAPES ARE THEN REOPEN-
$ ED WITH A PROBABILITY OF .2 WHENEVER SOLAR DROPS BELOW 40BTUH.
$ ATRIUM GLASS IS THE SAME AS OFFICE GLASS EXCEPT THAT IT DOES NOT
$ HAVE DRAPES. THERE ARE TWO MAIN SECTIONS OF GLASS 29' WIDE BY
$ 30' HIGH WITH OVERHANGS AND SIDE FINS. NOTICE THAT THE SKETCH
$ OF THE BUILDING INDICATES A LARGE OVERHANG WHICH WOULD BE VERY
$ DIFFICULT TO BUILD. THIS WAS THE WAY IT WAS SIMULATED AS THIS
$ METHOD IS EQUIVALENT TO MULTIPLE SURFACES THAT PROVIDE THE SAME
$ SHADING GEOMETRY.
$ INTERIORS CEILINGS ARE SIMULATED AS PART OF THE ROOF STRUCTURE ON THE TOP
$ FLOOR. PARTITIONS SIMULATE A GLASS WALL BETWEEN ATRIUM AND
$ OFFICE SPACES, BUT WALLS BETWEEN INTERIOR AND EXTERIOR OFFICES
$ ARE NOT DEFINED. WALLS BETWEEN THE EQUIPMENT ROOM AND OFFICES
$ HAVE A U-VALUE OF .28.
$ SPACE LOADS LIGHTING IS RECESSED FLUORSCENT NON VENTED AT 1.5 WATTS/SQFT
$ IN THE OFFICES AND 1 WATT/SQFT IN THE ATRIUM.
$ PEOPLE IN OFFICES IS INPUT AT 150SQFT/PERSON.
$ PEOPLE IN ATRIUM ARE SIX.
$ INFILTRATION IS SET AT 1 AIRCHANGES/HR WHEN FANS ARE OFF AND AT
$ .1 AIRCHANGE WHEN FANS ARE ON.
$ EQUIPMENT IN OFFICES IS SET AT 1 WATTS/SQFT.
$ CHICAGO DESIGN DAY - WORST CASE FOR TES SYSTEM - JULY 4TH WEEKEND THAT SPANS
$ A 7 DAY HOT SPELL - HEAVY SMOG - 10F DROP IN TEMPERATURE AT NIGHT
$ WHICH COMPARES TO 20F NORMALLY AND MINIMIZES RELEASE OF HEAT BY
$ CONVECTION AND RERADIATION.
HOT-SMOG-SUMMER = DESIGN-DAY
DRYBULB-HI = 98 DRYBULB-LO = 86
HOUR-HI = 15 HOUR-LO = 7
DEWPT-HI = 65.5 DEWPT-LO = 60
DHOUR-HI = 16 DHOUR-LO = 8
WIND-SPEED = 7.5 WIND-DIR = 10
CLOUD-AMOUNT = 0 CLOUD-TYPE = 0
CLEARNESS = 1 GROUND-T = 61 ..
COLD-CLOUDY-WINTER = DESIGN-DAY
DRYBULB-HI = 6 DRYBULB-LO = -4
HOUR-HI = 15 HOUR-LO = 2
DEWPT-HI = 6 DEWPT-LO = -4
DHOUR-HI = 16 DHOUR-LO = 3
WIND-SPEED = 15 WIND-DIR = 14
CLOUD-AMOUNT = 5 CLOUD-TYPE = 2
CLEARNESS = 1 GROUND-T = 46 ..
$ CONSTRUCTIONS
ROOF-O =LAYERS MAT=(BR01,IN76,CC03,AL33,AC03) I-F-R=.76 ..
ROOF-A =LAYERS MAT=(BR01,IN76,CC04) I-F-R .76 ..
OFF-ROF =CONSTRUCTION LAYERS ROOF-O ..
ATR-ROF =CONSTRUCTION LAYERS ROOF-A ..
WALL-1 =LAYERS MAT=(CC33,IN35,AL21,GP04,GP04) ..
WL1 =CONSTRUCTION LAYERS=WALL-1 ..
BW1 =CONSTRUCTION U=.05 ..
BW2 =CONSTRUCTION U=.0001 ..
WL2 =CONSTRUCTION U=1.05 $ ATRIUM GLASS PARTITIONS $ ..
WL3 =CONSTRUCTION U=.28 $ INTERIOR PARTITIONS $ ..
$ GLASS DESCRIPTION
GT1 =GLASS-TYPE GLASS-TYPE-CODE 5 PANES 2 ..
GT2 =GLASS-TYPE G-T-C 5 PANES 2 ..
$ SCHEDULES
OC1 =DAY-SCHEDULE (1,9) (0) (10,12) (1) (13,14) (.8)
(15,18) (.9) (19,24) (.1) ..
OC2 =DAY-SCHEDULE (1,24) (.1) ..
OCCUP =SCHEDULE THRU DEC 31 (WD) OC1 (WEH) OC2 ..
L1 =DAY-SCHEDULE (1,6) (.05) (7,12) (.9) (13,14) (.8)
(15,18) (.9) (19,21) (.2) (22,24) (.05) ..
L2 =DAY-SCHEDULE (1,24) (.05) ..
LT1 =SCHEDULE THRU DEC 31 (WD) L1 (WEH) L2 ..
ES1 =DAY-SCHEDULE (1,9) (0) (10,21) (.9) (22,24) (0) ..
ES2 =DAY-SCHEDULE (1,24) (0) ..
EQ1 =SCHEDULE THRU DEC 31 (WD) ES1 (WEH) ES2 ..
I1 =DAY-SCHEDULE (1,9) (1) (10,21) (.1) (22,24) (1) ..
I2 =DAY-SCHEDULE (1,24) (1) ..
INFIL =SCHEDULE THRU DEC 31 (WD) I1 (WEH) I2 ..
SHADE-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.6) ..
COND-MULT =SCHEDULE THRU DEC 31 (ALL) (1,24) (.90) ..
CLOSE-SHADE =SCHEDULE THRU DEC 31 (ALL) (1,24) (40) ..
REOPEN-PROB =SCHEDULE THRU DEC 31 (ALL) (1,24) (.2) ..
$ SET DEFAULTS
SET-DEFAULT FOR EXTERIOR-WALL HEIGHT=10 AZIMUTH=180
CONSTRUCTION=WL1 ..
SET-DEFAULT FOR WINDOW HEIGHT=4 Y=4 GLASS-TYPE=GT1
MAX-SOLAR-SCH=CLOSE-SHADE SUN-CTRL-PROB .7
WIN-SHADE-TYPE=MOVABLE-INTERIOR
SHADING-SCHEDULE=SHADE-MULT
CONDUCT-SCHEDULE=COND-MULT
OPEN-SHADE-SCH=REOPEN-PROB ..
$ SPACE DESCRIPTION
OFFICE =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=70
EQUIPMENT-W/SQFT=1 EQUIP-SCHEDULE=EQ1
LIGHTING-W/SQFT=1.5 LIGHTING-SCHEDULE=LT1
INF-METHOD=AIR-CHANGE AIR-CHANGES/HR=.2
INF-SCHEDULE=INFIL LIGHTING-TYPE=SUS-FLUOR
PEOPLE-HG-LAT=200 PEOPLE-HG-SENS=250
PEOPLE-SCHEDULE=OCCUP AREA/PERSON=150 ..
ATRIUM =SPACE-CONDITIONS TEMPERATURE=(74) FLOOR-WEIGHT=100
LIGHTING-SCHEDULE=LT1
LIGHTING-TYPE=INCAND
LIGHTING-W/SQFT=1
NUMBER-OF-PEOPLE=6
PEOPLE-HEAT-GAIN= 550
PEOPLE-SCHEDULE = OCCUP
INF-SCHEDULE=INFIL AIR-CHANGES/HR=.2
INF-METHOD=AIR-CHANGE ..
BZ1 =SPACE S-C=OFFICE AREA=3230 VOLUME=29070
AZ=90 Y=200 ..
E1 =EXTERIOR-WALL WIDTH=200 ..
W1 =WINDOW WIDTH=200 ..
E1S =EXTERIOR-WALL W=17 AZ=90 X=200 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
BZ2 =SPACE S-C=OFFICE AREA=1660 VOLUME=14940
AZ=180 X=100 Y=200 ..
E2 =EXTERIOR-WALL WIDTH=100 ..
W2 =WINDOW WIDTH=100 ..
UNDERGROUND-FLOOR AREA=1660 CONS=BW1 ..
BZ3 =SPACE LIKE BZ1 AZ=-90 X=100 Y=0 ..
E3 =EXTERIOR-WALL LIKE E1 ..
W3 =WINDOW LIKE W1 ..
E3S =EXTERIOR-WALL W=17 AZ=270 Y=17 ..
UNDERGROUND-FLOOR AREA=3230 CONS=BW1 ..
TZ1 =SPACE LIKE BZ1 Z=10 ..
R1 =ROOF H=17 W=200 AZ=180 TILT=0 Z=10
CONS=OFF-ROF ..
EXTERIOR-WALL LIKE E1 ..
WINDOW LIKE W1 ..
EXTERIOR-WALL LIKE E1S ..
TZ2 =SPACE LIKE BZ2 Z=10 ..
ROOF LIKE R1 H=20 W=83 ..
EXTERIOR-WALL LIKE E2 ..
WINDOW LIKE W2 ..
TZ3 =SPACE LIKE BZ3 Z=10 ..
ROOF LIKE R1 H=17 W=180 ..
EXTERIOR-WALL LIKE E3 ..
WINDOW LIKE W3 ..
EXTERIOR-WALL LIKE E3S ..
IZ1 =SPACE S-C=OFFICE AREA=3540 VOLUME=70800
AZ=90 X=17 Y=180 ..
IN1 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ1 CONS=WL2 ..
IN2 =INTERIOR-WALL AREA=1200 NEXT-TO ATZ2 CONS=WL2 ..
IN3 =INTERIOR-WALL AREA=586 NEXT-TO EQUIP-RM CONS=WL3 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 Y=18 Z=20 ..
EXTERIOR-WALL H=20 W=18 AZ=90 X=180 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
IZ2 =SPACE LIKE IZ1 AZ=-90 X=83 Y=0 ..
INTERIOR-WALL LIKE IN1 NEXT-TO ATZ1 ..
INTERIOR-WALL LIKE IN2 NEXT-TO ATZ2 ..
INTERIOR-WALL LIKE IN3 ..
EXTERIOR-WALL H=20 W=18 AZ=270 Y=18 ..
ROOF LIKE R1 H=18 W=180 Z=20 ..
ROOF LIKE R1 H=15 W=20 X=160 Y=18 Z=20 ..
UNDERGROUND-FLOOR AREA=3540 CONS=BW1 ..
ATZ1 =SPACE S-C=ATRIUM AREA=1800 VOLUME=16200
X=35 Y=40 ..
ATROOF-1 =ROOF HEIGHT=66.6 WIDTH=30
AZIMUTH=0 TILT=26 X=30 Y=60 Z=20
CONS=ATR-ROF ..
E4 =EXTERIOR-WALL H=14.5 W=60 AZ=270 Y=60 Z=20 ..
E5 =EXTERIOR-WALL LIKE E4 AZ=90 X=30 Y=0 ..
F1 =UNDERGROUND-FLOOR AREA=1800 CONS=BW2 ..
FRAME-A =EXTERIOR-WALL HEIGHT=29 WIDTH=30 Z=20 ..
WINDOW-A =WINDOW H=28.9 W=29.9 X=.05 Y=.05 GLASS-TYPE=GT2
OVERHANG-A=6 OH-B=0 OH-D=48.5 OH-W=42
OVERHANG-ANGLE=116 LEFT-FIN-A=0 L-F-B=0
L-F-H=30 L-F-D=3 RIGHT-FIN-A=0 R-F-B=0
R-F-H=30 R-F-D=3 ..
EXTERIOR-WALL LIKE FRAME-A HEIGHT=10.7 W=30 Z=9.3 ..
WINDOW LIKE WINDOW-A H=10.6 W=29.9 L-F-H=10.7
R-F-H=10.7 ..
ATZ2 =SPACE LIKE ATZ1 SOURCE-BTU/HR=0.0 Y=100 ..
ATROOF-2 =ROOF LIKE ATROOF-1 ..
EXTERIOR-WALL LIKE E4 ..
EXTERIOR-WALL LIKE E5 ..
UNDERGROUND-FLOOR LIKE F1 ..
FRAME-B =EXTERIOR-WALL LIKE FRAME-A ..
WINDOW-B =WINDOW LIKE WINDOW-A ..
EQUIP-RM =SPACE ZONE-TYPE=UNCONDITIONED
AREA=1200 VOLUME=17580 X=35 ..
EXTERIOR-WALL HEIGHT=20 WIDTH=30 ..
ROOF H=41.2 W=30 CONS=OFF-ROF
TILT=15 Z=9.3 X=30 Y=40 AZIMUTH=0 ..
INTERIOR-WALL AREA=279 CONS=WL3 NEXT-TO ATZ1 ..
UNDERGROUND-FLOOR AREA=1200 CONS=BW1 ..
END ..
COMPUTE LOADS ..
INPUT SYSTEMS ..
SYSTEMS-REPORT SUMMARY (SS-D,SS-A,SS-J) ..
$ ALL ELECTRIC HVAC SYSTEMS DESCRIPTION
$ DESIGN TEMPS ATRIUM COOLING 80F-SUMMER, 68F-WINTER HEATING SETBACK 65F
$ OFFICE COOLING 76F HEATING 72F
$ SYSTEM TYPE THE OFFICE IS SERVED BY A VAVS SYSTEM WITH THE BASEBOARD
$ THERMOSTATICALLY CONTROLLED AND HAS AN DRYBULB ECONOMIZER
$ WITH A 68F DRYBULB-LIMIT. THIS SYSTEM OPERATES FROM 7AM
$ TO 6PM ON WEEKDAYS DURING SPRING, FALL, AND WINTER. HOWEVER,
$ IN SUMMER IT OPERATES ON SUNDAY AFTERNOON TO MITIGATE THE
$ MONDAY MORNING STARTUP LOAD, ESPECIALLY AFTER A HOT WEEKEND.
$ THE OPEN ATRIA IS SERVED BY 1 PKG VARIABLE TEMPERATURE -
$ CONSTANT VOLUME SYSTEM (PSZ) WITH AIR/AIR HEAT PUMP. THE
$ PSZ SYSTEM HAS AN ECONOMIZER WITH ENTHALPY-LIMIT, PLUS
$ A DRYBULB-LIMIT AND AN ECONO-LOCKOUT WHICH PROTECTS
$ THE COMPRESSOR FROM BURNOUT ON LOW EVAPORATOR LOADING.
$ THE HEAT PUMP DEFROST-TYPE IS REVERSE-CYCLE AND CONTROLLED
$ BY ON-DEMAND.
$ AIR HANDLING UNIT SCHEDULES
NORM-DAYS = WEEK-SCHEDULE (WD) (1,5)(0)(6,7)(-999)(8,21)(1)(22,24)(0)
|
Products and Solutions 
